PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: Scytrin dai Kinthra <scytrin@gmail.com>
   3
   4 pkgname=st-git
   5 _pkgname=st
   6 pkgver=20150603.71fa10f
   7 pkgrel=1
   8 pkgdesc='Simple virtual terminal emulator for X'
   9 url='http://git.suckless.org/st/'
  10 arch=('i686' 'x86_64' 'armv7h')
  11 license=('MIT')
  12 depends=('libxft')
  13 makedepends=('ncurses' 'libxext' 'git')
  14 source=('git://git.suckless.org/st'
  15         'scrollback.patch')
  16 sha1sums=('SKIP'
  17           '2e10ac47eb020d50c7f861f3923bb4152255a027')
  18
  19 provides=("${_pkgname}")
  20 conflicts=("${_pkgname}")
  21
  22 pkgver() {
  23         cd "${srcdir}/${_pkgname}"
  24         git log -1 --format='%cd.%h' --date=short | tr -d -
  25 }
  26
  27 prepare() {
  28         cd "${srcdir}/${_pkgname}"
  29         patch -p1 -i ../scrollback.patch # http://st.suckless.org/patches/st-scrollback.diff
  30         sed \
  31                 -e '/char font/s/= .*/= "Fixed:pixelsize=13:style=SemiCondensed";/' \
  32                 -e '/char worddelimiters/s/= .*/= " '"'"'`\\\"()[]{}<>|";/' \
  33                 -e '/int defaultcs/s/= .*/= 1;/' \
  34                 -i config.def.h
  35         sed '/@tic/d' -i Makefile
  36 }
  37
  38 build() {
  39         cd "${srcdir}/${_pkgname}"
  40         make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
  41 }
  42
  43 package() {
  44         cd "${srcdir}/${_pkgname}"
  45         make PREFIX=/usr DESTDIR="${pkgdir}" install
  46         install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  47         install -Dm644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
  48         tic -s -o "${pkgdir}/usr/share/terminfo" st.info
  49 }