virtual/eldiron.nix

   1 {
   2   network = {
   3     description = "Immae's network";
   4     enableRollback = true;
   5   };
   6
   7   # Full backup:
   8   # The star after /var/lib/* avoids deleting all folders in case of problem
   9   # rsync -e "ssh -i /root/.ssh/id_charon_vpn" -aAXvz --delete --numeric-ids --super --rsync-path="sudo rsync" /var/lib/* immae@immae.eu:
  10   eldiron = { config, pkgs, mylibs, myconfig, ... }:
  11     with mylibs;
  12     let
  13         mypkgs = pkgs.callPackage ./packages.nix {
  14           inherit checkEnv fetchedGit fetchedGithub;
  15         };
  16     in
  17   {
  18     _module.args = {
  19       mylibs = import ../libs.nix;
  20       myconfig = {
  21         ips = {
  22           main = "176.9.151.89";
  23           production = "176.9.151.154";
  24           integration = "176.9.151.155";
  25         };
  26       };
  27     };
  28
  29     imports = [
  30       ./modules/certificates.nix
  31       ./modules/gitolite.nix
  32       ./modules/gitweb
  33       ./modules/databases.nix
  34       ./modules/websites
  35       ./modules/websites/phpfpm
  36     ];
  37     services.myGitolite.enable = true;
  38     services.myGitweb.enable = true;
  39     services.myDatabases.enable = true;
  40     services.myWebsites.production.enable = true;
  41     services.myWebsites.integration.enable = true;
  42
  43     networking = {
  44       firewall = {
  45         enable = true;
  46         allowedTCPPorts = [ 22 9418 ];
  47       };
  48     };
  49
  50     deployment = {
  51       targetEnv = "hetzner";
  52       hetzner = {
  53         #robotUser = "defined in HETZNER_ROBOT_USER";
  54         #robotPass = "defined in HETZNER_ROBOT_PASS";
  55         mainIPv4 = myconfig.ips.main;
  56         partitions = ''
  57           clearpart --all --initlabel --drives=sda,sdb
  58
  59           part swap1 --recommended --label=swap1 --fstype=swap --ondisk=sda
  60           part swap2 --recommended --label=swap2 --fstype=swap --ondisk=sdb
  61
  62           part raid.1 --grow --ondisk=sda
  63           part raid.2 --grow --ondisk=sdb
  64
  65           raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2
  66         '';
  67       };
  68     };
  69
  70     environment.systemPackages = let
  71       # FIXME: move it to nextcloud
  72       occ = pkgs.writeScriptBin "nextcloud-occ" ''
  73         #! ${pkgs.stdenv.shell}
  74         cd ${mypkgs.nextcloud.webRoot}
  75         NEXTCLOUD_CONFIG_DIR="${mypkgs.nextcloud.webRoot}/config" \
  76           exec \
  77           ${pkgs.php}/bin/php \
  78           -c ${pkgs.php}/etc/php.ini \
  79           occ $*
  80         '';
  81     in [
  82       pkgs.telnet
  83       pkgs.htop
  84       pkgs.vim
  85       occ
  86     ];
  87
  88     security.acme.certs."eldiron".extraDomains = {
  89       "db-1.immae.eu" = null;
  90       "tools.immae.eu" = null;
  91       "cloud.immae.eu" = null;
  92       "dav.immae.eu" = null;
  93     };
  94
  95     services.openssh.extraConfig = ''
  96       AuthorizedKeysCommand     /etc/ssh/ldap_authorized_keys
  97       AuthorizedKeysCommandUser nobody
  98       '';
  99
 100     services.ympd = mypkgs.ympd.config // { enable = false; };
 101
 102     services.myPhpfpm = {
 103       phpPackage = pkgs.php;
 104       phpOptions = ''
 105         session.save_path = "/var/lib/php/sessions"
 106         session.gc_maxlifetime = 60*60*24*15
 107         session.cache_expire = 60*24*30
 108         '';
 109       extraConfig = ''
 110         log_level = notice
 111         '';
 112       poolPhpConfigs = {
 113         nextcloud = mypkgs.nextcloud.phpFpm.phpConfig;
 114       };
 115       poolConfigs = {
 116         adminer = mypkgs.adminer.phpFpm.pool;
 117         nextcloud = mypkgs.nextcloud.phpFpm.pool;
 118         mantisbt = mypkgs.mantisbt.phpFpm.pool;
 119         ttrss = mypkgs.ttrss.phpFpm.pool;
 120         roundcubemail = mypkgs.roundcubemail.phpFpm.pool;
 121         davical = mypkgs.davical.phpFpm.pool;
 122       };
 123     };
 124
 125     system.activationScripts = {
 126       nextcloud = mypkgs.nextcloud.activationScript;
 127       ttrss = mypkgs.ttrss.activationScript;
 128       roundcubemail = mypkgs.roundcubemail.activationScript;
 129       httpd = ''
 130         install -d -m 0755 /var/lib/acme/acme-challenge
 131         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions
 132         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/adminer
 133         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/mantisbt
 134         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/davical
 135         '';
 136     };
 137
 138     environment.etc."ssh/ldap_authorized_keys" = let
 139       ldap_authorized_keys =
 140         assert checkEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 141         wrap {
 142           name = "ldap_authorized_keys";
 143           file = ./ldap_authorized_keys.sh;
 144           vars = {
 145             LDAP_PASS = builtins.getEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 146             GITOLITE_SHELL = "${pkgs.gitolite}/bin/gitolite-shell";
 147             ECHO = "${pkgs.coreutils}/bin/echo";
 148           };
 149           paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.gnused pkgs.coreutils ];
 150         };
 151     in {
 152       enable = true;
 153       mode = "0755";
 154       user = "root";
 155       source = ldap_authorized_keys;
 156     };
 157
 158     systemd.services.tt-rss = {
 159       description = "Tiny Tiny RSS feeds update daemon";
 160       serviceConfig = {
 161         User = "wwwrun";
 162         ExecStart = "${pkgs.php}/bin/php ${mypkgs.ttrss.webRoot}/update.php --daemon";
 163         StandardOutput = "syslog";
 164         StandardError = "syslog";
 165         PermissionsStartOnly = true;
 166       };
 167
 168       wantedBy = [ "multi-user.target" ];
 169       requires = ["postgresql.service"];
 170       after = ["network.target" "postgresql.service"];
 171     };
 172   };
 173 }