modules/private/gitolite/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3     cfg = config.myServices.gitolite;
   4 in {
   5   options.myServices.gitolite = {
   6     enable = lib.mkEnableOption "my gitolite service";
   7     gitoliteDir = lib.mkOption {
   8       type = lib.types.str;
   9       default = "/var/lib/gitolite";
  10     };
  11   };
  12
  13   config = lib.mkIf cfg.enable {
  14     myServices.chatonsProperties.services.gitolite = {
  15       file.datetime = "2022-08-21T10:01:00";
  16       service = {
  17         name = "Gitolite";
  18         description = "Gitolite allows you to setup git hosting on a central server, with fine-grained access control and many more powerful features.";
  19         website = "https://git.immae.eu";
  20         logo = "https://git.immae.eu/cgit-css/favicon.ico";
  21         status.level = "OK";
  22         status.description = "OK";
  23         registration."" = ["MEMBER" "CLIENT"];
  24         registration.load = "OPEN";
  25         install.type = "PACKAGE";
  26         guide.user = "https://www.immae.eu/docs/forge-logicielle.html";
  27       };
  28       software = {
  29         name = "Gitolite";
  30         website = "https://gitolite.com/gitolite/";
  31         license.url = "https://github.com/sitaramc/gitolite/blob/master/COPYING";
  32         license.name = "GNU General Public License v2.0";
  33         version = pkgs.gitolite.version;
  34         source.url = "https://github.com/sitaramc/gitolite";
  35       };
  36     };
  37     myServices.ssh.modules = [{
  38       snippet = builtins.readFile ./ldap_gitolite.sh;
  39       dependencies = [ pkgs.gitolite ];
  40     }];
  41     networking.firewall.allowedTCPPorts = [ 9418 ];
  42
  43     secrets.keys."gitolite/ldap_password" = {
  44       user = "gitolite";
  45       group = "gitolite";
  46       permissions = "0400";
  47       text = config.myEnv.tools.gitolite.ldap.password;
  48     };
  49
  50     services.gitDaemon = {
  51       enable = true;
  52       user = "gitolite";
  53       group = "gitolite";
  54       basePath = "${cfg.gitoliteDir}/repositories";
  55     };
  56
  57     system.activationScripts.gitolite = let
  58       deps = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.coreutils ];
  59       gitolite_ldap_groups = pkgs.runCommand "gitolite_ldap_groups.sh" {
  60         buildInputs = [ pkgs.makeWrapper ];
  61       } ''
  62         makeWrapper "${./gitolite_ldap_groups.sh}" "$out" \
  63           --prefix PATH : ${lib.makeBinPath deps} \
  64           --set LDAP_PASS_PATH ${config.secrets.fullPaths."gitolite/ldap_password"}
  65         '';
  66     in {
  67       deps = [ "users" ];
  68       text = ''
  69         if [ -d ${cfg.gitoliteDir} ]; then
  70           ln -sf ${gitolite_ldap_groups} ${cfg.gitoliteDir}/gitolite_ldap_groups.sh
  71           chmod g+rx ${cfg.gitoliteDir}
  72         fi
  73         if [ -f ${cfg.gitoliteDir}/projects.list ]; then
  74           chmod g+r ${cfg.gitoliteDir}/projects.list
  75         fi
  76       '';
  77     };
  78
  79     users.users.wwwrun.extraGroups = [ "gitolite" ];
  80     users.users.gitolite.extraGroups = [ "keys" ];
  81
  82     users.users.gitolite.packages = let
  83       python-packages = python-packages: with python-packages; [
  84         simplejson
  85         apprise
  86         urllib3
  87         sleekxmpp
  88         pyyaml
  89       ];
  90     in
  91       [
  92         (pkgs.python38.withPackages python-packages)
  93         pkgs.nettools
  94         pkgs.findutils
  95       ];
  96     # Installation: https://git.immae.eu/mantisbt/view.php?id=93
  97     services.gitolite = {
  98       enable = true;
  99       adminPubkey = config.myEnv.sshd.rootKeys.immae_dilion;
 100     };
 101   };
 102 }