Use password store to store environment

[perso/Immae/Config/Nix.git] / nixops / modules / websites / piedsjaloux / default.nix

{ lib, pkgs, config, myconfig, mylibs, ... }:
let
    piedsjaloux = pkgs.callPackage ./piedsjaloux.nix { inherit (mylibs) fetchedGitPrivate; };
    piedsjaloux_dev  = piedsjaloux {
      config = myconfig.env.websites.piedsjaloux.integration;
    };
    piedsjaloux_prod = piedsjaloux {
      config = myconfig.env.websites.piedsjaloux.production;
    };

    cfg = config.services.myWebsites.PiedsJaloux;
in {
  options.services.myWebsites.PiedsJaloux = {
    production = {
      enable = lib.mkEnableOption "enable PiedsJaloux's website in production";
    };
    integration = {
      enable = lib.mkEnableOption "enable PiedsJaloux's website in integration";
    };
  };

  imports = [
    ../commons/stats.nix
  ];

  config = lib.mkMerge [
    (lib.mkIf cfg.production.enable {
      services.myWebsites.commons.stats.enable = true;
      services.myWebsites.commons.stats.sites = [
        {
          name = "piedsjaloux.fr";
          conf = ./goaccess.conf;
        }
      ];

      security.acme.certs."piedsjaloux" = config.services.myCertificates.certConfig // {
        domain = "piedsjaloux.fr";
        extraDomains = {
          "www.piedsjaloux.fr" = null;
        };
      };

      services.myPhpfpm.poolConfigs.piedsjaloux_prod = piedsjaloux_prod.phpFpm.pool;
      system.activationScripts.piedsjaloux_prod = piedsjaloux_prod.activationScript;
      services.myWebsites.production.modules = piedsjaloux_prod.apache.modules;
      services.myWebsites.production.vhostConfs.piedsjaloux = {
        certName    = "piedsjaloux";
        hosts       = [ "piedsjaloux.fr" "www.piedsjaloux.fr" ];
        root        = piedsjaloux_prod.webRoot;
        extraConfig = [ piedsjaloux_prod.apache.vhostConf ];
      };
    })
    (lib.mkIf cfg.integration.enable {
      security.acme.certs."eldiron".extraDomains."piedsjaloux.immae.eu" = null;
      services.myPhpfpm.poolConfigs.piedsjaloux_dev = piedsjaloux_dev.phpFpm.pool;
      system.activationScripts.piedsjaloux_dev = piedsjaloux_dev.activationScript;
      services.myWebsites.integration.modules = piedsjaloux_dev.apache.modules;
      services.myWebsites.integration.vhostConfs.piedsjaloux = {
        certName    = "eldiron";
        hosts       = [ "piedsjaloux.immae.eu" ];
        root        = piedsjaloux_dev.webRoot;
        extraConfig = [ piedsjaloux_dev.apache.vhostConf ];
      };
    })
  ];
}