Add chatons infos

[perso/Immae/Config/Nix.git] / modules / private / websites / tools / cloud / default.nix

{ lib, pkgs, config,  ... }:
let
  phpPackage = (pkgs.php74.withExtensions({ enabled, all }: enabled ++ [ all.redis all.apcu all.opcache all.imagick ])).override { extraConfig = ''
    apc.enable_cli = 1
    '';
  };
  nextcloud = pkgs.webapps.nextcloud_22.withApps (a: [
    a.apporder a.audioplayer a.bookmarks a.calendar a.carnet a.contacts
    a.cookbook a.deck a.extract a.files_markdown a.files_readmemd a.files_mindmap
    a.flowupload a.gpxedit a.gpxpod a.keeweb a.maps a.metadata a.music
    a.notes a.passman a.polls a.spreed a.tasks
  ]);
  env = config.myEnv.tools.nextcloud;
  varDir = "/var/lib/nextcloud";
  cfg = config.myServices.websites.tools.cloud;
  phpFpm = rec {
    basedir = builtins.concatStringsSep ":" ([ nextcloud varDir ] ++ nextcloud.apps);
    pool = {
      "listen.owner" = "wwwrun";
      "listen.group" = "wwwrun";
      "pm" = "dynamic";
      "pm.max_children" = "60";
      "pm.start_servers" = "2";
      "pm.min_spare_servers" = "2";
      "pm.max_spare_servers" = "3";
      "pm.process_idle_timeout" = "60";

      "php_admin_value[output_buffering]" = "0";
      "php_admin_value[max_execution_time]" = "1800";
      "php_admin_value[zend_extension]" = "opcache";
      #already enabled by default?
      #"php_value[opcache.enable]" = "1";
      "php_value[opcache.enable_cli]" = "1";
      "php_value[opcache.interned_strings_buffer]" = "8";
      "php_value[opcache.max_accelerated_files]" = "10000";
      "php_value[opcache.memory_consumption]" = "128";
      "php_value[opcache.save_comments]" = "1";
      "php_value[opcache.revalidate_freq]" = "1";
      "php_admin_value[memory_limit]" = "512M";

      "php_admin_value[open_basedir]" = "/run/wrappers/bin/sendmail:${basedir}:/proc/meminfo:/dev/urandom:/proc/self/fd:/tmp";
      "php_admin_value[session.save_path]" = "${varDir}/phpSessions";
    };
  };
in {
  options.myServices.websites.tools.cloud = {
    enable = lib.mkEnableOption "enable cloud website";
  };

  config = lib.mkIf cfg.enable {
    myServices.chatonsProperties.hostings.nextcloud = {
      file.datetime = "2022-08-21T19:50:00";
      hosting = {
        name = "Nextcloud";
        description = "The self-hosted productivity platform that keeps you in control";
        website = "https://cloud.immae.eu/";
        logo = "https://cloud.immae.eu/core/img/favicon.ico";
        type = "INSTANCE";
        status.level = "OK";
        status.description = "OK";
        registration.load = "OPEN";
        install.type = "PACKAGE";
      };
    };
    myServices.chatonsProperties.services.nextcloud = {
      file.datetime = "2022-08-21T19:50:00";
      service = {
        name = "Nextcloud";
        description = "The self-hosted productivity platform that keeps you in control";
        website = "https://cloud.immae.eu/";
        logo = "https://cloud.immae.eu/core/img/favicon.ico";
        status.level = "OK";
        status.description = "OK";
        registration."" = ["MEMBER" "CLIENT"];
        registration.load = "OPEN";
        install.type = "PACKAGE";
        guide.user = "https://www.immae.eu/docs/nextcloud.html";
      };
      software = {
        name = "Nextcloud";
        website = "https://nextcloud.com/";
        license.url = "https://github.com/nextcloud/server/blob/master/COPYING";
        license.name = "GNU Affero General Public License v3.0";
        version = nextcloud.version;
        source.url = "https://github.com/nextcloud/server";
        modules = map (a: a.appName) nextcloud.apps;
      };
    };
    services.websites.env.tools.modules = [ "proxy_fcgi" ];

    services.websites.env.tools.vhostConfs.cloud = {
      certName    = "eldiron";
      addToCerts  = true;
      hosts       = ["cloud.immae.eu" ];
      root        = nextcloud;
      extraConfig = [
        ''
          SetEnvIf Authorization "(.*)" HTTP_AUTHORIZATION=$1
          <Directory ${nextcloud}>
            AcceptPathInfo On
            DirectoryIndex index.php
            Options FollowSymlinks
            Require all granted
            AllowOverride all

            <IfModule mod_headers.c>
              Header always set Strict-Transport-Security "max-age=15552000; includeSubDomains; preload"
            </IfModule>
            <FilesMatch "\.php$">
              CGIPassAuth on
              SetHandler "proxy:unix:${config.services.phpfpm.pools.nextcloud.socket}|fcgi://localhost"
            </FilesMatch>

          </Directory>
        ''
      ];
    };

    secrets.keys."webapps/tools-nextcloud" = {
      user = "wwwrun";
      group = "wwwrun";
      permissions = "0600";
      # This file is not actually included, see activationScript below
      text = ''
        <?php
        include('${nextcloud}/version.php');
        $CONFIG = array (
          // FIXME: change this value when nextcloud starts getting slow
          'instanceid' => '${env.instance_id}',
          'datadirectory' => '/var/lib/nextcloud/',
          'passwordsalt' => '${env.password_salt}',
          'debug' => false,
          'dbtype' => 'pgsql',
          'version' => implode($OC_Version, '.'),
          'dbname' => '${env.postgresql.database}',
          'dbhost' => '${env.postgresql.socket}',
          'dbtableprefix' => 'oc_',
          'dbuser' => '${env.postgresql.user}',
          'dbpassword' => '${env.postgresql.password}',
          'installed' => true,
          'maxZipInputSize' => 0,
          'allowZipDownload' => true,
          'forcessl' => true,
          'theme' => ${"''"},
          'remember_login_cookie_lifetime' => 60*60*24*30,
          'session_keepalive' => true,
          'session_lifefime' => 60*60*24*30,
          'maintenance' => false,
          'trusted_domains' => 
          array (
            0 => 'cloud.immae.eu',
          ),
          'secret' => '${env.secret}',
          'appstoreenabled' => false,
          'appstore.experimental.enabled' => true,
          'loglevel' => 2,
          'trashbin_retention_obligation' => 'auto',
          'htaccess.RewriteBase' => '/',
          'mail_smtpmode' => 'sendmail',
          'mail_smtphost' => '127.0.0.1',
          'mail_smtpname' => ''',
          'mail_smtppassword' => ''',
          'mail_from_address' => 'nextcloud',
          'mail_smtpauth' => false,
          'mail_domain' => 'tools.immae.eu',
          'memcache.local' => '\\OC\\Memcache\\APCu',
          'memcache.locking' => '\\OC\\Memcache\\Redis',
          'filelocking.enabled' => true,
          'redis' => 
          array (
            'host' => '${env.redis.socket}',
            'port' => 0,
            'dbindex' => ${env.redis.db},
          ),
          'overwrite.cli.url' => 'https://cloud.immae.eu',
          'ldapIgnoreNamingRules' => false,
          'ldapProviderFactory' => '\\OCA\\User_LDAP\\LDAPProviderFactory',
          'has_rebuilt_cache' => true,
        );
      '';
    };
    users.users.root.packages = let
      occ = pkgs.writeScriptBin "nextcloud-occ" ''
        #! ${pkgs.stdenv.shell}
        cd ${nextcloud}
        NEXTCLOUD_CONFIG_DIR="${nextcloud}/config" \
          exec \
          sudo -E -u wwwrun ${phpPackage}/bin/php \
          -c ${phpPackage}/etc/php.ini \
          occ $*
        '';
    in [ occ ];

    system.activationScripts.nextcloud = {
      deps = [ "secrets" ];
      text = let
        confs = lib.attrsets.mapAttrs (n: v: pkgs.writeText "${n}.json" (builtins.toJSON v)) nextcloud.otherConfig;
      in
        ''
        install -m 0755 -o wwwrun -g wwwrun -d ${varDir}
        install -m 0750 -o wwwrun -g wwwrun -d ${varDir}/phpSessions
        ${builtins.concatStringsSep "\n" (lib.attrsets.mapAttrsToList (n: v:
          "install -D -m 0644 -o wwwrun -g wwwrun -T ${v} ${varDir}/config/${n}.json"
          ) confs)}
        #install -D -m 0600 -o wwwrun -g wwwrun -T ${config.secrets.fullPaths."webapps/tools-nextcloud"} ${varDir}/config/config.php
      '';
    };

    services.phpfpm.pools.nextcloud = {
      user = "wwwrun";
      group = "wwwrun";
      settings = phpFpm.pool;
      inherit phpPackage;
    };

    services.cron = {
      enable = true;
      systemCronJobs = let
        script = pkgs.writeScriptBin "nextcloud-cron" ''
          #! ${pkgs.stdenv.shell}
          export LOCALE_ARCHIVE=/run/current-system/sw/lib/locale/locale-archive
          export PATH=/run/wrappers/bin:$PATH
          ${phpPackage}/bin/php -d memory_limit=2048M -f ${nextcloud}/cron.php
          '';
      in [
        ''
          */15 * * * * wwwrun ${script}/bin/nextcloud-cron
        ''
      ];
    };
  };
}