Rework webhooks

[perso/Immae/Config/Nix.git] / modules / private / websites / isabelle / aten_integration.nix

{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.isabelle.aten_integration;
  cfg = config.myServices.websites.isabelle.aten_integration;
  ftpRoot = "/var/lib/isabelle_aten_integration";
  phpRoot = "${ftpRoot}/php";
  webRoot = "${phpRoot}/public";
  varDir = "${ftpRoot}/var";
  sessionDir = "${ftpRoot}/sessions";
  packagePath = "/var/lib/ftp/release.immae.eu/buildbot/IsabelleAten";
  branch = "test";
in {
  options.myServices.websites.isabelle.aten_integration.enable = lib.mkEnableOption "enable Aten's website in integration";

  config = lib.mkIf cfg.enable {
    services.phpfpm.pools.isabelle_aten_integration = {
      user = config.services.httpd.Inte.user;
      group = config.services.httpd.Inte.group;
      settings = {
        "listen.owner" = config.services.httpd.Inte.user;
        "listen.group" = config.services.httpd.Inte.group;
        "php_admin_value[open_basedir]" = builtins.concatStringsSep ":" [
          ftpRoot
          config.secrets.fullPaths."websites/isabelle/aten_integration"
          "/tmp"
        ];
        "php_admin_value[session.save_path]" = sessionDir;
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";
      };
      phpEnv = {
        SYMFONY_DEBUG_MODE = "\"yes\"";
      };
      phpPackage = pkgs.php72;
    };
    systemd.services."phpfpm-isabelle_aten_integration" = {
      after = lib.mkAfter ["postgresql.service"];
      wants = ["postgresql.service"];
      path = lib.mkAfter [ pkgs.gnutar pkgs.gzip pkgs.php72 ];
      preStart = let
        script = pkgs.writeScriptBin "isabelle-aten-integration" ''
          #! ${pkgs.stdenv.shell}

          [ -f ${packagePath}/${branch}.tar.gz ] || exit 1

          cd ${ftpRoot}
          if ! [ -f .tarball_sum ] || ! sha256sum -c .tarball_sum; then
            tar -xf ${packagePath}/${branch}.tar.gz --one-top-level=php_new
            if [ -d php ]; then
              mv php php_old
            fi
            mv php_new php
          fi
          cd php
          rm -rf var/{log,cache}
          ln -sf ${varDir}/{log,cache} var/
          SYMFONY_ENV=dev APP_ENV=dev ./bin/console --env=dev cache:clear --no-warmup
          sha256sum ${packagePath}/${branch}.tar.gz > ${ftpRoot}/.tarball_sum
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Inte.user} ${script}/bin/isabelle-aten-integration";
      postStart = let
        script = pkgs.writeScriptBin "isabelle-aten-integration-post" ''
          #! ${pkgs.stdenv.shell}

          cd ${ftpRoot}
          if [ -d php_old ]; then
            rm -rf php_old
          fi
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Inte.user} ${script}/bin/isabelle-aten-integration-post";
      serviceConfig.TimeoutStartSec="infinity";
    };
    services.filesWatcher.phpfpm-isabelle_aten_integration = {
      restart = true;
      paths = [ "${packagePath}/${branch}.tar.gz" ];
    };

    system.activationScripts.isabelle_aten_integration = {
      deps = ["users"];
      text = ''
        install -m 0700 -o ${config.services.httpd.Inte.user} -g ${config.services.httpd.Inte.group} -d ${ftpRoot} ${sessionDir}
      '';
    };

    secrets.keys."websites/isabelle/aten_integration" = {
      user = config.services.httpd.Inte.user;
      group = config.services.httpd.Inte.group;
      permissions = "0400";
      text = let
        # cf:
        #   https://secure.php.net/manual/fr/function.parse-url.php
        #   vendor/doctrine/dbal/lib/Doctrine/DBAL/DriverManager.php#parseDatabaseUrlQuery
        psql_url = with secrets.postgresql; "pdo-pgsql://${user}:${password}@invalid:${port}/${database}?host=${socket}";
      in ''
        SetEnv APP_ENV      "${secrets.environment}"
        SetEnv APP_SECRET   "${secrets.secret}"
        SetEnv DATABASE_URL "${psql_url}"
        '';
    };
    services.websites.env.integration.vhostConfs.isabelle_aten_integration = {
      certName    = "integration";
      addToCerts  = true;
      hosts       = [ "aten.ic.immae.dev" ];
      root        = webRoot;
      extraConfig = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.isabelle_aten_integration.socket}|fcgi://localhost"
        </FilesMatch>

        Include ${config.secrets.fullPaths."websites/isabelle/aten_integration"}

        <Location />
          Use LDAPConnect
          Require ldap-group   cn=ic.immae.dev,cn=httpd,ou=services,dc=immae,dc=eu
          ErrorDocument 401 "<html><meta http-equiv=\"refresh\" content=\"0;url=https://aten.pro\"></html>"
        </Location>

        <Location /backend>
          Use LDAPConnect
          Require ldap-group   cn=ic.immae.dev,cn=httpd,ou=services,dc=immae,dc=eu
          ErrorDocument 401 "<html><meta http-equiv=\"refresh\" content=\"0;url=https://aten.pro\"></html>"
        </Location>

        <Directory ${webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
          DirectoryIndex index.php
          FallbackResource /index.php
        </Directory>
        ''
      ];
    };
  };
}