Finish removal of php-application module

[perso/Immae/Config/Nix.git] / modules / private / websites / connexionswing / production.nix

{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.connexionswing.production;
  cfg = config.myServices.websites.connexionswing.production;
  ftpRoot = "/var/lib/connexionswing_production";
  phpRoot = "${ftpRoot}/php";
  webRoot = "${phpRoot}/web";
  varDir = "${ftpRoot}/var";
  packagePath = "/var/lib/ftp/release.immae.eu/buildbot/Connexionswing";
  branch = "master";
in {
  options.myServices.websites.connexionswing.production.enable = lib.mkEnableOption "enable Connexionswing's website in production";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "connexionswing.com"; } ];
    services.phpfpm.pools.connexionswing_production = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      settings = {
        "listen.owner" = config.services.httpd.Prod.user;
        "listen.group" = config.services.httpd.Prod.group;
        "php_admin_value[open_basedir]" = builtins.concatStringsSep ":" [
          ftpRoot
          config.secrets.fullPaths."websites/connexionswing/production"
          "/run/wrappers/bin/sendmail"
          "/tmp"
        ];
        "php_admin_value[session.save_handler]" = "redis";
        "php_admin_value[session.save_path]" = "'unix:///run/redis-php-sessions/redis.sock?persistent=1&prefix=Connexionswing:Production:'";
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpPackage = pkgs.php72.withExtensions ({ enabled, all }: enabled ++ [all.redis]);
    };
    systemd.services."phpfpm-connexionswing_production" = {
      after = lib.mkAfter ["mysql.service"];
      wants = ["mysql.service"];
      path = lib.mkAfter [ pkgs.gnutar pkgs.gzip pkgs.php72 ];
      preStart = let
        script = pkgs.writeScriptBin "connexionswing-production-pre" ''
          #! ${pkgs.stdenv.shell}

          [ -f ${packagePath}/${branch}.tar.gz ] || exit 1

          cd ${ftpRoot}
          if ! [ -f .tarball_sum ] || ! sha256sum -c .tarball_sum; then
            tar -xf ${packagePath}/${branch}.tar.gz --one-top-level=php_new
            if [ -d php ]; then
              mv php php_old
            fi
            mv php_new php
          fi
          cd php
          rm -rf var/{logs,cache}
          ln -sf ${varDir}/var/{logs,cache} var/
          ln -sf ${varDir}/{medias,uploads} web/images/
          ln -sf ${config.secrets.fullPaths."websites/connexionswing/production"} app/config/parameters.yml
          SYMFONY_ENV=${secrets.environment} ./bin/console --env=${secrets.environment} cache:clear --no-warmup
          sha256sum ${packagePath}/${branch}.tar.gz > ${ftpRoot}/.tarball_sum
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/connexionswing-production-pre";
      postStart = let
        script = pkgs.writeScriptBin "connexionswing-production-post" ''
          #! ${pkgs.stdenv.shell}

          cd ${ftpRoot}
          if [ -d php_old ]; then
            rm -rf php_old
          fi
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/connexionswing-production-post";
      serviceConfig.TimeoutStartSec="infinity";
    };
    services.filesWatcher.phpfpm-connexionswing_production = {
      restart = true;
      paths = [ "${packagePath}/${branch}.tar.gz" ];
    };

    system.activationScripts.connexionswing_production = {
      deps = ["users"];
      text = ''
        install -m 0700 -o ${config.services.httpd.Prod.user} -g ${config.services.httpd.Prod.group} -d ${ftpRoot}
      '';
    };

    secrets.keys."websites/connexionswing/production" = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      permissions = "0400";
      text = ''
        # This file is auto-generated during the composer install
        parameters:
            database_host: ${secrets.mysql.host}
            database_port: ${secrets.mysql.port}
            database_name: ${secrets.mysql.database}
            database_user: ${secrets.mysql.user}
            database_password: ${secrets.mysql.password}
            database_server_version: ${config.myServices.databases.mariadb.package.mysqlVersion}
            mailer_transport: sendmail
            mailer_host: null
            mailer_user: null
            mailer_password: null
            subscription_email: ${secrets.email}
            allow_robots: true
            secret: ${secrets.secret}
        services:
          swiftmailer.mailer.default.transport:
              class:     Swift_SendmailTransport
              arguments: ['/run/wrappers/bin/sendmail -bs']
      '';
    };

    services.websites.env.production.vhostConfs.connexionswing_production = {
      certName     = "connexionswing";
      certMainHost = "connexionswing.com";
      hosts        = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
      root         = webRoot;
      extraConfig  = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.connexionswing_production.socket}|fcgi://localhost"
        </FilesMatch>

        <Directory ${varDir}/medias>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        <Directory ${varDir}/uploads>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        Use Stats connexionswing.com

        <Directory ${webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}