WIP upgrade

[perso/Immae/Config/Nix.git] / modules / private / websites / christophe_carpentier / agorakit / default.nix

{ varDir, secretsPath
, composerEnv, fetchFromGitHub, fetchurl, php74 }:
let
  composerEnv' = composerEnv.override { php = php74; };
  app = composerEnv'.buildPackage (
    import ./php-packages.nix { composerEnv = composerEnv'; inherit fetchurl; } //
    rec {
      version = "master-7d86952";
      pname = "agorakit";
      name = "${pname}-${version}";
      src = fetchFromGitHub {
        owner = "agorakit";
        repo  = "agorakit";
        rev = "7d86952623b2f9effff20657c81c6eb0f6de8bdf";
        sha256 = "10h0krhzgamc9di0xw6fv97cm49krvm6a58wg3db1qkcin62hvsw";
      };
      noDev = true;
      postInstall = ''
        cd $out
        patch -p1 < ${././sort_groups.patch}
        ln -sf ${secretsPath} .env
        mkdir -p oldvars/bootstrap oldvars/public_storage
        mv storage oldvars
        mv bootstrap/cache oldvars/bootstrap

        ln -sf ${varDir}/public_storage public/storage
        ln -sf ${varDir}/bootstrap/cache bootstrap
        ln -sf ${varDir}/storage storage
        '';
      passthru = {
        inherit varDir secretsPath;
        webRoot = "${app}/public";
      };
    });
in app