Add monitoring

5 files changed, 232 insertions, 0 deletions

diff --git a/modules/profile/manifests/monitoring/commands.pp b/modules/profile/manifests/monitoring/commands.pp
new file mode 100644
index 0000000..7e9683f
--- /dev/null
+++ b/modules/profile/manifests/monitoring/commands.pp
@@ -0,0 +1,63 @@
+class profile::monitoring::commands inherits profile::monitoring {
+  ensure_packages(["monitoring-plugins"])
+
+  file { "/etc/naemon/monitoring-plugins":
+    ensure => "directory",
+    owner  => "naemon",
+    group  => "naemon",
+    mode   => "0700",
+  }
+
+  file { "/etc/naemon/monitoring-plugins/check_command":
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    mode   => "0700",
+    source => "puppet:///modules/profile/monitoring/check_command",
+  }
+
+  file { "/etc/naemon/monitoring-plugins/check_md_raid":
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    mode   => "0700",
+    source => "puppet:///modules/profile/monitoring/check_md_raid",
+  }
+
+  Nagios_command {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  nagios_command {
+    "check-host-alive":
+      command_line => '$USER1$/check_ping -H $HOSTADDRESS$ -w 3000.0,80% -c 5000.0,100% -p 5';
+    "check_local_disk":
+      command_line => '$USER1$/check_disk -w $ARG1$ -c $ARG2$ -p $ARG3$';
+    "check_local_procs":
+      command_line => '$USER1$/check_procs -w $ARG1$ -c $ARG2$ -s $ARG3$';
+    "check_local_load":
+      command_line => '$USER1$/check_load -w $ARG1$ -c $ARG2$';
+    "check_local_swap":
+      command_line => '$USER1$/check_swap -n ok -w $ARG1$ -c $ARG2$';
+    "check_ntp":
+      command_line => '$USER1$/check_ntp_time -H 0.arch.pool.ntp.org';
+    "check_md_raid":
+      command_line => '$USER2$/check_md_raid';
+    "check_command_output":
+      command_line => '$USER2$/check_command -c "$ARG1$" -o "$ARG2$" $ARG3$',
+      require      => File["/etc/naemon/monitoring-plugins/check_command"];
+  }
+
+  unless empty($naemon_url) {
+    nagios_command {
+      "notify-master":
+        command_line => '/etc/naemon/send_nrdp.sh -H "$HOSTADDRESS$" -s "$SERVICEDESC$" -S "$SERVICESTATEID$" -o "$SERVICEOUTPUT$"',
+        require      => File["/etc/naemon/send_nrdp.sh"];
+    }
+  }
+}
diff --git a/modules/profile/manifests/monitoring/contacts.pp b/modules/profile/manifests/monitoring/contacts.pp
new file mode 100644
index 0000000..284d51c
--- /dev/null
+++ b/modules/profile/manifests/monitoring/contacts.pp
@@ -0,0 +1,15 @@
+class profile::monitoring::contacts {
+  Nagios_contactgroup {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  nagios_contactgroup { "admins":
+    alias => "System administrators",    
+  }
+
+}
diff --git a/modules/profile/manifests/monitoring/hosts.pp b/modules/profile/manifests/monitoring/hosts.pp
new file mode 100644
index 0000000..306fe3e
--- /dev/null
+++ b/modules/profile/manifests/monitoring/hosts.pp
@@ -0,0 +1,43 @@
+class profile::monitoring::hosts {
+  $real_hostname = lookup("base_installation::real_hostname")
+
+  Nagios_hostgroup {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  Nagios_host {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  nagios_hostgroup { "linux-servers":
+    alias   => "Linux Servers",
+    members => [$real_hostname],
+  }
+
+  $host_linux_server = {
+    check_command         => "check-host-alive",
+    check_interval        => 5,
+    check_period          => "24x7",
+    contact_groups        => "admins",
+    max_check_attempts    => "10",
+    notification_interval => "120",
+    notification_options  => "d,u,r",
+    retry_interval        => "1",
+  }
+
+  nagios_host { $real_hostname:
+    address => $real_hostname;
+  default: * => $host_linux_server,
+  }
+
+}
diff --git a/modules/profile/manifests/monitoring/services.pp b/modules/profile/manifests/monitoring/services.pp
new file mode 100644
index 0000000..39c2def
--- /dev/null
+++ b/modules/profile/manifests/monitoring/services.pp
@@ -0,0 +1,89 @@
+class profile::monitoring::services {
+  $real_hostname = lookup("base_installation::real_hostname")
+
+  Nagios_service {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  $service_generic = {
+    active_checks_enabled        => "1",
+    check_freshness              => "0",
+    check_interval               => "10",
+    check_period                 => "24x7",
+    contact_groups               => "admins",
+    event_handler_enabled        => "1",
+    flap_detection_enabled       => "1",
+    is_volatile                  => "0",
+    max_check_attempts           => "3",
+    notification_interval        => "60",
+    notification_options         => "w,u,c,r",
+    notification_period          => "24x7",
+    notifications_enabled        => "1",
+    obsess_over_service          => "1",
+    passive_checks_enabled       => "1",
+    process_perf_data            => "1",
+    retain_nonstatus_information => "1",
+    retain_status_information    => "1",
+    retry_interval               => "2",
+  }
+
+
+  $service_local = merge($service_generic, {
+    host_name          => $real_hostname,
+    check_interval     => "5",
+    max_check_attempts => "4",
+    retry_interval     => "1",
+    })
+
+  sudo::conf {
+    default:
+      sudo_file_name => "naemon";
+    'naemon-fail2ban':
+      content => "naemon  ALL=(root) NOPASSWD: /usr/bin/fail2ban-client ping";
+  }
+
+  nagios_service {
+    default: * => $service_local;
+    "Size on root partition":
+      service_description => "Size on root partition",
+      check_command       => "check_local_disk!20%!10%!/";
+    "Total number of process":
+      service_description => "Total number of process",
+      check_command       => "check_local_procs!250!400!RSZDT";
+    "Average load":
+      service_description => "Average load",
+      check_command       => "check_local_load!8.0,8.0,8.0!10.0,10.0,10.0";
+    "Swap usage":
+      service_description => "Swap usage",
+      check_command       => "check_local_swap!20!10";
+    "fail2ban is active":
+      service_description => "fail2ban is active",
+      check_command       => "check_command_output!fail2ban-client ping!pong!-r root",
+      require             => Sudo::Conf["naemon-fail2ban"];
+    "NTP is activated and working":
+      service_description => "NTP is activated and working",
+      check_command       => "check_ntp";
+  }
+
+  if empty(find_file("/proc/mdstat")) {
+    nagios_service {
+      default: * => $service_local;
+      "No mdadm array is degraded":
+        ensure              => "absent",
+        service_description => "No mdadm array is degraded",
+        check_command       => "check_md_raid";
+    }
+  } else {
+    nagios_service {
+      default: * => $service_local;
+      "No mdadm array is degraded":
+        service_description => "No mdadm array is degraded",
+        check_command       => "check_md_raid";
+    }
+  }
+}
diff --git a/modules/profile/manifests/monitoring/times.pp b/modules/profile/manifests/monitoring/times.pp
new file mode 100644
index 0000000..fb61acc
--- /dev/null
+++ b/modules/profile/manifests/monitoring/times.pp
@@ -0,0 +1,22 @@
+class profile::monitoring::times {
+  Nagios_timeperiod {
+    ensure => "present",
+    owner  => "naemon",
+    group  => "naemon",
+    target => "/etc/naemon/objects.cfg",
+    notify => Service["naemon"],
+    before => Service["naemon"],
+  }
+
+  nagios_timeperiod { "24x7":
+    alias     => "24 Hours A Day, 7 Days A Week",
+    monday    => "00:00-24:00",
+    tuesday   => "00:00-24:00",
+    wednesday => "00:00-24:00",
+    thursday  => "00:00-24:00",
+    friday    => "00:00-24:00",
+    saturday  => "00:00-24:00",
+    sunday    => "00:00-24:00",
+  }
+
+}