blob: 1bd003de48731d005ec396a44dc156f62cd66b8f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: mar77i <mar77i at mar77i dot ch>
# Past Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Scytrin dai Kinthra <scytrin@gmail.com>
pkgname=st-git
_pkgname=st
pkgver=0.7.1.g023225e
pkgrel=1
pkgdesc='Simple virtual terminal emulator for X'
url='http://git.suckless.org/st/'
arch=('i686' 'x86_64')
license=('MIT')
options=('zipman')
depends=('libxft')
makedepends=('ncurses' 'libxext' 'git')
epoch=1
# include config.h and any patches you want to have applied here
source=('git://git.suckless.org/st')
sha1sums=('SKIP')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
pkgver() {
cd "${_pkgname}"
git describe --tags |sed 's/-/./g'
}
prepare() {
local file
cd "${_pkgname}"
sed \
-e '/char font/s/= .*/= "Fixed:pixelsize=13:style=SemiCondensed";/' \
-e '/char worddelimiters/s/= .*/= " '"'"'`\\\"()[]{}<>|";/' \
-e '/int defaultcs/s/= .*/= 1;/' \
-i config.def.h
sed \
-e 's/CPPFLAGS =/CPPFLAGS +=/g' \
-e 's/CFLAGS =/CFLAGS +=/g' \
-e 's/LDFLAGS =/LDFLAGS +=/g' \
-e 's/_BSD_SOURCE/_DEFAULT_SOURCE/' \
-i config.mk
sed '/@tic/d' -i Makefile
for file in "${source[@]}"; do
if [[ "$file" == "config.h" ]]; then
# add config.h if present in source array
# Note: this supersedes the above sed to config.def.h
cp "$srcdir/$file" .
elif [[ "$file" == *.diff || "$file" == *.patch ]]; then
# add all patches present in source array
patch -Np1 <"$srcdir/$(basename ${file})"
fi
done
}
build() {
cd "${_pkgname}"
make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}
package() {
cd "${_pkgname}"
make PREFIX=/usr DESTDIR="${pkgdir}" install
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
}
|
