6 files changed, 670 insertions, 0 deletions

diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Formatters.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Formatters.hs
new file mode 100644
index 0000000..6f0210b
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Formatters.hs
@@ -0,0 +1,88 @@
+{-# LANGUAGE OverloadedStrings #-}
+
+module Text.Edifact.Scaffolder.Commons.Formatters
+  ( -- *
+    fMessageCode
+  , fMessageParserFunction
+  , fGroupCode
+  , fSegmentCode
+  , fSegmentParserFunction
+  , fCompositeCode
+  , fCompositeParserFunction
+  , fSimpleCode
+  , fSimpleParserFunction
+
+    -- *
+  , fParserSignature
+  , fParserDeclaration
+    -- *
+  , fModuleName
+  , fPosition
+  , fPresence
+    -- *
+  , quoted
+  , simpleQuoted
+  , parens
+  , notYetImplemented
+  ) where
+
+import           Text.Edifact.Scaffolder.Commons.Types
+
+import           Formatting                            as F
+
+fMessageCode:: Format r (MessageCode -> r)
+fMessageCode = mapf getMessageCode F.string
+
+fMessageParserFunction :: Format r (MessageCode -> r)
+fMessageParserFunction = mapf getMessageCode ("message" % F.string)
+
+fGroupCode :: Format r (GroupCode -> r)
+fGroupCode = mapf getGroupCode F.string
+
+fSegmentCode :: Format r (SegmentCode -> r)
+fSegmentCode = mapf getSegmentCode F.string
+
+fSegmentParserFunction :: Format r (SegmentCode -> r)
+fSegmentParserFunction = mapf getSegmentCode ("segment" % F.string)
+
+fCompositeCode :: Format r (CompositeCode -> r)
+fCompositeCode = mapf getCompositeCode F.string
+
+fCompositeParserFunction :: Format r (CompositeCode -> r)
+fCompositeParserFunction = mapf getCompositeCode ("composite" % F.string)
+
+fSimpleCode :: Format r (SimpleCode -> r)
+fSimpleCode = mapf getSimpleCode F.string
+
+fSimpleParserFunction :: Format r (SimpleCode -> r)
+fSimpleParserFunction = mapf getSimpleCode ("simple" % F.string)
+
+fParserSignature :: Format r a -> Format r a
+fParserSignature f = f % " :: Parser Value"
+
+fParserDeclaration :: Format r a -> Format r a
+fParserDeclaration f = f % " ="
+
+fModuleName :: Format r (ModuleName -> r)
+fModuleName = mapf getModuleName string
+
+fPosition :: Format r (Position -> r)
+fPosition = mapf getPosition F.string
+
+fPresence :: Format r (Presence -> r)
+fPresence =
+  let f Mandatory = "mandatory"
+      f Optional  = "optional "
+  in mapf f F.string
+
+quoted :: Format r a -> Format r a
+quoted f = "\"" % f % "\""
+
+simpleQuoted :: Format r a -> Format r a
+simpleQuoted f = "'" % f % "'"
+
+parens :: Format r a -> Format r a
+parens f = "(" % f % ")"
+
+notYetImplemented :: Format r a -> Format r a
+notYetImplemented desc = "notYetImplemented " % quoted (desc % " not yet implemented")
diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Language.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Language.hs
new file mode 100644
index 0000000..214ee43
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Language.hs
@@ -0,0 +1,286 @@
+{-# LANGUAGE DerivingStrategies         #-}
+{-# LANGUAGE GeneralizedNewtypeDeriving #-}
+{-# LANGUAGE OverloadedLists            #-}
+{-# LANGUAGE OverloadedStrings          #-}
+
+module Text.Edifact.Scaffolder.Commons.Language
+  ( -- *
+    saveHaskellModule
+  , includeSpecification
+    -- *
+  , scaffoldModule
+    -- *
+  , getRootModuleName
+  , getRootModuleNameFor
+    -- *
+  , scaffoldElements
+  , ElementWithDefinition
+    -- *
+  , parentModule
+    -- *
+  , haddockDependencies
+    -- *
+  , reexportDependencies
+    -- *
+  , importDependencies
+  , importCombinators
+  , importNotYetImplementedHelper
+    -- *
+  , moduleDeclaration
+  , Export(..)
+    -- *
+  , reexportAlias
+  , singleImport
+  , ImportGroup(..)
+  , Import(..)
+  , ImportName(..)
+  , ModuleAlias(..)
+  , LanguageExtension(..)
+  ) where
+
+import           Text.Edifact.Scaffolder.Commons.Formatters (fModuleName,
+                                                             parens,
+                                                             simpleQuoted)
+import           Text.Edifact.Scaffolder.Commons.Logging    (say)
+import           Text.Edifact.Scaffolder.Commons.Text       (commaSeparated,
+                                                             extensions,
+                                                             formatSpecification,
+                                                             indent, newline)
+import           Text.Edifact.Scaffolder.Commons.Types      (LanguageExtension (..),
+                                                             ModuleName (..),
+                                                             Scaffolding,
+                                                             getRevision,
+                                                             hostModule,
+                                                             revision,
+                                                             targetDirectory,
+                                                             (<.>))
+
+import           Control.Monad                              ((>=>))
+import           Control.Monad.IO.Class                     (liftIO)
+import           Control.Monad.Reader                       (asks)
+import           Data.Bifunctor                             (bimap)
+import           Data.Foldable                              (traverse_)
+import           Data.List                                  (intercalate,
+                                                             uncons)
+import           Data.List.NonEmpty                         (NonEmpty, nonEmpty)
+import qualified Data.List.NonEmpty                         as NE (cons, toList)
+import           Data.List.Split                            (splitOn)
+import           Data.String                                (IsString (..))
+import           Data.Text                                  as T (Text, drop,
+                                                                  lines,
+                                                                  unlines)
+import qualified Data.Text.IO                               as TIO (readFile,
+                                                                    writeFile)
+import           Data.Tuple                                 (swap)
+import           Formatting                                 as F (Format,
+                                                                  bprint, later,
+                                                                  mapf, sformat,
+                                                                  stext, (%))
+import           System.Directory                           (createDirectoryIfMissing)
+import           System.FilePath                            ((</>))
+import           System.Process                             (callCommand)
+
+getRootModuleName :: Scaffolding ModuleName
+getRootModuleName =
+  let prefix host rev = host <.> ModuleName (getRevision rev)
+  in asks (prefix . hostModule) <*> asks revision
+
+getRootModuleNameFor :: ModuleName -> Scaffolding ModuleName
+getRootModuleNameFor name =
+  let suffix root = root <.> name
+  in suffix <$> getRootModuleName
+
+saveHaskellModule :: ModuleName -> [Text] -> Scaffolding ()
+saveHaskellModule mn body =
+  let sources = T.unlines body
+      saveModule file = liftIO (saveFile file >> stylishHaskell file)
+      saveFile = flip TIO.writeFile sources
+      stylishHaskell file = callCommand ("stylish-haskell -i " <> file)
+      doNothing = pure ()
+  in say ("module " % fModuleName) mn >> mkSourceFile mn >>= maybe doNothing saveModule
+
+mkSourceFile :: ModuleName -> Scaffolding (Maybe FilePath)
+mkSourceFile = locateSourceFile >=> traverse prepareHierarchy
+
+type FileInDirectory = (Directory, FileName)
+type Directory = FilePath
+type FileName = FilePath
+
+prepareHierarchy :: FileInDirectory -> Scaffolding FilePath
+prepareHierarchy (directory, file) =
+  let fullPath = directory </> file
+  in fullPath <$ liftIO (createDirectoryIfMissing True directory)
+
+locateSourceFile :: ModuleName -> Scaffolding (Maybe FileInDirectory)
+locateSourceFile (ModuleName mn) =
+  let hierarchy = splitOn "." mn
+      toFile n = n <> ".hs"
+      path :: Directory -> Maybe (Directory, FileName)
+      path directory = fmap toFile . swap . fmap (foldl (</>) directory . reverse) <$> uncons (reverse hierarchy)
+  in asks (path . targetDirectory)
+
+includeSpecification :: FilePath -> Scaffolding [Text]
+includeSpecification = fmap (formatSpecification . T.lines) . liftIO . TIO.readFile
+
+type ElementWithDefinition elt = (FilePath, elt)
+
+scaffoldElements :: (NonEmpty (ElementWithDefinition element) -> Scaffolding ())
+                 -> (          ElementWithDefinition element  -> Scaffolding ())
+                 -> ([         ElementWithDefinition element] -> Scaffolding ())
+scaffoldElements parentScaffolder elementScaffolder =
+  let doNothing = pure ()
+      scaffolder elts = parentScaffolder elts >> traverse_ elementScaffolder elts
+  in maybe doNothing scaffolder . nonEmpty
+
+parentModule :: ModuleName -> ModuleAlias -> (ModuleName -> element -> ModuleName) -> NonEmpty (ElementWithDefinition element) -> Scaffolding ()
+parentModule elementName alias nameModule elements =
+  getRootModuleNameFor elementName >>= generateRootModule alias nameModule (snd <$> elements)
+
+generateRootModule :: ModuleAlias -> (ModuleName -> element -> ModuleName) -> NonEmpty element -> ModuleName -> Scaffolding ()
+generateRootModule alias nameModule codes mn =
+  let importElement code = ImportAll (ImportAs (nameModule mn code) alias)
+      imports = [ ImportGroup (importElement <$> codes) ]
+      exports = [ reexportAlias alias ]
+  in saveHaskellModule mn $
+       moduleDeclaration mn exports imports
+
+haddockDependencies :: Format Text (elt -> Text) -> NonEmpty elt -> Scaffolding [Text]
+haddockDependencies formatter elts =
+  let formattedDependencies = commaSeparated . fmap (sformat (simpleQuoted formatter))
+      formatHaddock = sformat ("-- Dependencies: " % F.stext % ".")
+  in pure [ "--"
+          , formatHaddock (formattedDependencies elts)
+          ]
+
+reexportDependencies :: Format Text (elt -> Text) -> NonEmpty elt -> Scaffolding [Export]
+reexportDependencies formatter =
+  let mkReexport = Name . sformat formatter
+      prependTitle = NE.cons (Comment "* Dependencies")
+  in pure . NE.toList . prependTitle . fmap mkReexport
+
+importDependencies :: ModuleName -> Format Text (elt -> Text) -> NonEmpty elt -> Scaffolding Import
+importDependencies moduleName formatter elts =
+  let imports = NE.toList (sformat formatter <$> elts)
+      mkImport mn = Import (BasicImport mn) imports
+  in mkImport <$> getRootModuleNameFor moduleName
+
+importCombinators :: ImportGroup
+importCombinators =
+  ImportGroup
+    [ ImportAll "Text.Edifact.Parsing"
+    , Import    "Text.Edifact.Types"   [ "Value" ]
+    ]
+
+importNotYetImplementedHelper :: ImportGroup
+importNotYetImplementedHelper =
+  ImportGroup
+    [ Import "Text.Edifact.Parsing.Commons" [ "notYetImplemented" ]
+    ]
+
+moduleDeclaration :: ModuleName -> [Export] -> [ImportGroup] -> [Text]
+moduleDeclaration moduleName exports imports =
+  let decl mn [] = [sformat ("module " % fModuleName % " where") mn]
+      decl mn ex = sformat ("module " % fModuleName) mn
+                 : renderExports ex
+  in intercalate newline [ decl moduleName exports
+                         , renderImports imports
+                         ]
+
+machineGeneratedWarning :: [Text]
+machineGeneratedWarning =
+  [ "---- Machine generated code."
+  , "---- Output of edi-parser-scaffolder"
+  ]
+
+scaffoldModule :: ModuleName -> [LanguageExtension] -> [Export] -> [ImportGroup] -> [Text] -> Scaffolding ()
+scaffoldModule mn exts exports imports code =
+  saveHaskellModule mn $
+    intercalate newline
+      [ extensions exts
+      , machineGeneratedWarning
+      , moduleDeclaration mn exports imports
+      , code
+      ]
+
+renderExports :: [Export] -> [Text]
+renderExports exports =
+  let formatExport (First e)     = sformat ("  " % fExport) e
+      formatExport (Following e) = sformat (", " % fExport) e
+      formatExport (Skipped e)   = sformat ("  " % fExport) e
+      fExport =
+        let f (Comment t) = bprint ("-- " % stext) t
+            f (Name    t) = bprint stext t
+        in later f
+      parensOnFirstLine [] = []
+      parensOnFirstLine (firstLine : rest) = ("(" <> T.drop 1 firstLine) : rest
+      ls = parensOnFirstLine (formatExport <$> tag exports) <> [ ") where" ]
+  in indent <$> ls
+
+data Export = Name    Text
+            | Comment Text
+
+instance IsString Export where
+  fromString = Name . fromString
+
+data Tag a = First     a
+           | Following a
+           | Skipped   a
+
+tag :: [Export] -> [Tag Export]
+tag =
+  let skipAll = fmap Skipped
+      tagFirst []             = []
+      tagFirst (elt : others) = First elt : tagOthers others
+      tagOthers = fmap tagOther
+      tagOther v | isComment v = Skipped v
+                 | otherwise   = Following v
+      merge (xs, ys) = xs <> ys
+  in merge . bimap skipAll tagFirst . span isComment
+
+isComment :: Export -> Bool
+isComment (Comment _) = True
+isComment _           = False
+
+newtype ModuleAlias = ModuleAlias { getModuleAlias :: Text } deriving newtype (IsString)
+
+singleImport :: Import -> ImportGroup
+singleImport = ImportGroup . pure
+
+newtype ImportGroup = ImportGroup (NonEmpty Import) deriving newtype Semigroup
+
+data Import = Import    ImportName [Text]
+            | ImportAll ImportName
+
+data ImportName = BasicImport       ModuleName
+                | ImportAs          ModuleName ModuleAlias
+                | ImportQualified   ModuleName
+                | ImportQualifiedAs ModuleName ModuleAlias
+
+instance IsString ImportName where
+  fromString = BasicImport . fromString
+
+renderImports :: [ImportGroup] -> [Text]
+renderImports = intercalate newline . fmap renderImportGroup
+
+reexportAlias :: ModuleAlias -> Export
+reexportAlias = Name . sformat ("module " % fModuleAlias)
+
+renderImportGroup :: ImportGroup -> [Text]
+renderImportGroup (ImportGroup imports) = NE.toList (renderImport <$> imports)
+
+renderImport :: Import -> Text
+renderImport (ImportAll name)            = sformat fImportName name
+renderImport (Import    name references) =
+  sformat (fImportName % " " % parens stext) name (commaSeparated references)
+
+fImportName :: Format r (ImportName -> r)
+fImportName =
+  let
+      build (BasicImport       name)       = bprint ("import " % fModuleName) name
+      build (ImportAs          name alias) = bprint ("import " % fModuleName % " as " % fModuleAlias) name alias
+      build (ImportQualified   name)       = bprint ("import qualified " % fModuleName) name
+      build (ImportQualifiedAs name alias) = bprint ("import qualified " % fModuleName % " as " % fModuleAlias) name alias
+  in later build
+
+fModuleAlias :: Format r (ModuleAlias -> r)
+fModuleAlias = mapf getModuleAlias stext
diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Logging.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Logging.hs
new file mode 100644
index 0000000..1287f7f
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Logging.hs
@@ -0,0 +1,11 @@
+module Text.Edifact.Scaffolder.Commons.Logging
+  ( say
+  ) where
+
+import           Control.Monad.IO.Class (MonadIO, liftIO)
+import qualified Data.Text.Lazy.Builder as TLB (toLazyText)
+import qualified Data.Text.Lazy.IO      as TLIO (putStrLn)
+import           Formatting             as F (Format, runFormat)
+
+say :: MonadIO m => Format (m ()) a -> a
+say m = runFormat m (liftIO . TLIO.putStrLn . TLB.toLazyText)
diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Parsing.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Parsing.hs
new file mode 100644
index 0000000..24f8f80
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Parsing.hs
@@ -0,0 +1,122 @@
+{-# LANGUAGE FlexibleContexts #-}
+{-# LANGUAGE TupleSections    #-}
+
+module Text.Edifact.Scaffolder.Commons.Parsing
+  ( -- *
+    maybeParse
+  , skipBeginning
+  , single
+  , silent
+    -- *
+  , listElements
+    -- *
+  , presenceParser
+  , stringToPresenceParser
+    -- *
+  , messageCodeParser
+    -- *
+  , scanDependencies
+  , scan
+  , scanUntil
+  ) where
+
+import           Text.Edifact.Scaffolder.Commons.Logging (say)
+import           Text.Edifact.Scaffolder.Commons.Types
+
+import           Control.Monad.IO.Class                  (liftIO)
+import           Control.Monad.Identity                  (Identity)
+import           Control.Monad.Reader                    (asks, local)
+import           Data.Bifunctor                          (first)
+import           Data.List                               (sort)
+import           Data.List.NonEmpty                      (NonEmpty, nonEmpty)
+import           Data.Maybe                              (catMaybes)
+import           Data.String                             (fromString)
+import           Data.Text                               (Text)
+import           Formatting                              as F (shown)
+import           System.Directory                        (listDirectory)
+import           System.FilePath                         ((</>))
+import           Text.Parsec                             (Parsec, SourceName,
+                                                          Stream, anyChar, char,
+                                                          choice, count,
+                                                          endOfLine, eof,
+                                                          lookAhead, many,
+                                                          many1, manyTill,
+                                                          oneOf, optionMaybe,
+                                                          runParser, string,
+                                                          try, upper, (<?>))
+
+maybeParse :: (Show a, Stream s Identity t, Monoid u) => SourceName -> Parsec s u a -> s -> Scaffolding (Maybe a)
+maybeParse source parser input =
+  let interpretParsingResult (Right v) _     = pure (Just v)
+      interpretParsingResult e         True  = Nothing <$ say shown e
+      interpretParsingResult _         False = pure Nothing
+      shouldDebug = asks debugParsing
+  in shouldDebug >>= interpretParsingResult (runParser parser mempty source input)
+
+-- | Disable parsing error logging locally
+silent :: Scaffolding a -> Scaffolding a
+silent = local disableDebugging
+
+-- | Let you traverse a directory and filter files matching a parser.
+-- The filename is then paired with the matched value
+listElements :: (Show elt, Ord elt) => FilePath -> Parsec String () elt -> Scaffolding [(FilePath, elt)]
+listElements subpath parser = do
+  home <- getSpecificationHome
+  let directory = home </> subpath
+  files <- sort <$> liftIO (listDirectory directory)
+  let prependDirectory f = directory </> f
+  fmap (first prependDirectory) . catMaybes <$> traverse (extractElement parser) files
+
+getSpecificationHome :: Scaffolding FilePath
+getSpecificationHome =
+  let concatenate path (Revision rev) = path </> rev
+  in asks (concatenate . specificationsHome) <*> asks revision
+
+extractElement :: Show elt => Parsec String () elt -> FilePath -> Scaffolding (Maybe (FilePath, elt))
+extractElement parser path = silent (fmap (path,) <$> maybeParse path parser path)
+
+skipBeginning :: Stream s Identity Char => Parsec s () a -> Parsec s () a
+skipBeginning p = manyTill anyChar (try (lookAhead p)) *> p
+
+single :: Stream s Identity Char => Parsec s u a -> Parsec s u [a]
+single = count 1
+
+presenceParser :: Stream s Identity Char => Parsec s u Presence
+presenceParser =
+  choice [ Mandatory <$ char 'M'
+         , Optional  <$ char 'C'
+         ] <?> "Presence"
+
+stringToPresenceParser :: Stream s Identity Char => Parsec s u Text
+stringToPresenceParser = fromString <$>
+        manyTill anyChar (try $ lookAhead $ many1 (string " ") >> presenceParser >> string " " >> many (oneOf " 0123456789"))
+        <?> "Description"
+
+messageCodeParser :: Stream s Identity Char => Parsec s u MessageCode
+messageCodeParser = fromString <$> count 6 upper
+
+scanDependencies :: (Monoid u, Show result) => FilePath -> Parsec String u [result] -> Scaffolding (Maybe (NonEmpty result))
+scanDependencies file parser =
+  let readLines = liftIO (readFile file)
+  in readLines >>= fmap (nonEmpty =<<) . maybeParse file parser
+
+scan :: Stream s Identity Char => [Parsec s u [a]] -> Parsec s u [a]
+scan scanners =
+  let parsers = (scanLine <$> scanners) <> [skipLine]
+      end = choice [ () <$ try endOfLine
+                   , () <$ eof
+                   ]
+      scanLine p = optionMaybe (try p) <* end
+      skipLine = Nothing <$ manyTill anyChar end
+  in concat . catMaybes <$> manyTill (choice parsers) eof
+
+scanUntil :: Stream s Identity Char => [Parsec s u a] -> Parsec s u a
+scanUntil scanners =
+  let parsers = scanLine <$> scanners
+      end = choice [ () <$ try endOfLine
+                   , () <$ eof
+                   ]
+      searching = choice $ fmap (() <$) parsers <> [ () <$ eof ]
+      scanLine p = p <* end
+      skipLine = manyTill anyChar end
+  in manyTill skipLine (try $ lookAhead searching) >> try (choice parsers)
diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Text.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Text.hs
new file mode 100644
index 0000000..ef4e805
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Text.hs
@@ -0,0 +1,91 @@
+{-# LANGUAGE DerivingStrategies         #-}
+{-# LANGUAGE GeneralizedNewtypeDeriving #-}
+{-# LANGUAGE OverloadedStrings          #-}
+
+module Text.Edifact.Scaffolder.Commons.Text
+  ( -- *
+    indent
+  , quote
+  , haskellList
+  , commaSeparated
+    -- *
+  , newline
+    -- *
+  , formatSpecification
+    -- *
+  , extensions
+  ) where
+
+
+import           Text.Edifact.Scaffolder.Commons.Types (LanguageExtension (..))
+
+import           Control.Category                      ((>>>))
+import           Data.Char                             (isSpace)
+import           Data.List                             (dropWhileEnd)
+import           Data.String                           (IsString)
+import           Data.Text                             (Text)
+import qualified Data.Text                             as T (all, dropWhileEnd,
+                                                             null)
+import           Formatting                            as F (mapf, sformat,
+                                                             stext, string, (%))
+
+formatSpecification :: [Text] -> [Text]
+formatSpecification = cleanEmptyLines
+                  >>> fmap quoteLine
+                  >>> prependQuote
+
+prependQuote :: [Text] -> [Text]
+prependQuote ls =
+  [ "-- | Derived from this specification:"
+  , "--"
+  ] <> ls
+
+cleanEmptyLines :: [Text] -> [Text]
+cleanEmptyLines = dropWhile blank >>> dropWhileEnd blank
+
+blank :: Text -> Bool
+blank t = T.null t || T.all isSpace t
+
+quoteLine :: Text -> Text
+quoteLine = haskellQuote >>> cleanWhitespaces
+
+haskellQuote :: Text -> Text
+haskellQuote line = "-- > " <> line
+
+cleanWhitespaces :: Text -> Text
+cleanWhitespaces = T.dropWhileEnd (== ' ')
+
+indent :: Text -> Text
+indent t = "  " <> t
+
+quote :: Text -> Text
+quote t = "'" <> t <> "'"
+
+haskellList :: [Text] -> [Text]
+haskellList =
+  let prefix :: Int -> Text -> Text
+      prefix 1 dep = sformat ("[ " % F.stext) dep
+      prefix _ dep = sformat (", " % F.stext) dep
+      suffix deps = deps <> ["]"]
+  in suffix . zipWith prefix [1..]
+
+newtype CommaSeparated = CommaSeparated { getCommaSeparated :: Text } deriving newtype (IsString, Eq)
+
+instance Semigroup CommaSeparated where
+  t1 <> "" = t1
+  "" <> t2 = t2
+  t1 <> t2 = CommaSeparated (getCommaSeparated t1 <> ", " <> getCommaSeparated t2)
+
+instance Monoid CommaSeparated where
+  mempty = ""
+
+commaSeparated :: Foldable f => f Text -> Text
+commaSeparated = getCommaSeparated . foldMap CommaSeparated
+
+newline :: [Text]
+newline = [""]
+
+extensions :: [LanguageExtension] -> [Text]
+extensions =
+  let fExtension = "{-# LANGUAGE " % mapf getLanguageExtension F.string % " #-}"
+  in fmap (sformat fExtension)
diff --git a/scaffolder/src/Text/Edifact/Scaffolder/Commons/Types.hs b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Types.hs
new file mode 100644
index 0000000..4d1c0a6
--- /dev/null
+++ b/scaffolder/src/Text/Edifact/Scaffolder/Commons/Types.hs
@@ -0,0 +1,72 @@
+{-# LANGUAGE DerivingStrategies         #-}
+{-# LANGUAGE GeneralizedNewtypeDeriving #-}
+
+module Text.Edifact.Scaffolder.Commons.Types
+  ( -- * Codes of elements
+    MessageCode(..)
+  , GroupCode(..)
+  , SegmentCode(..)
+  , SegmentName(..)
+  , CompositeCode (..)
+  , CompositeName (..)
+  , SimpleCode(..)
+  , SimpleName(..)
+    -- * Ordering of elements
+  , Position(..)
+    -- * Attributes
+  , Presence(..)
+    -- *
+  , ModuleName(..)
+  , (<.>)
+    -- *
+  , LanguageExtension(..)
+    -- *
+  , Scaffolding
+  , Revision(..)
+  , ScaffoldingEnv(..)
+  , disableDebugging
+  ) where
+
+import           Control.Monad.Reader (ReaderT)
+import           Data.String          (IsString)
+
+newtype MessageCode   = MessageCode   { getMessageCode   :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype GroupCode     = GroupCode     { getGroupCode     :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype SegmentCode   = SegmentCode   { getSegmentCode   :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype SegmentName   = SegmentName   { getSegmentName   :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype CompositeCode = CompositeCode { getCompositeCode :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype CompositeName = CompositeName { getCompositeName :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype SimpleCode    = SimpleCode    { getSimpleCode    :: String } deriving newtype (Show, Eq, Ord, IsString)
+newtype SimpleName    = SimpleName    { getSimpleName    :: String } deriving newtype (Show, Eq, Ord, IsString)
+
+newtype Position = Position { getPosition :: String } deriving newtype (Show, Eq, Ord, IsString)
+
+data Presence = Mandatory
+              | Optional
+                deriving (Show, Eq, Ord)
+
+newtype ModuleName = ModuleName { getModuleName :: String } deriving newtype (Show, Eq, IsString)
+
+instance Semigroup ModuleName where
+  (<>) = (<.>)
+
+(<.>) :: ModuleName -> ModuleName -> ModuleName
+(ModuleName parent) <.> (ModuleName child) = ModuleName (parent <> "." <> child)
+
+newtype LanguageExtension = LanguageExtension { getLanguageExtension :: String } deriving newtype IsString
+
+type Scaffolding = ReaderT ScaffoldingEnv IO
+
+newtype Revision = Revision { getRevision :: String } deriving newtype (Show, Eq, IsString)
+
+data ScaffoldingEnv =
+  ScaffoldingEnv
+    { revision           :: Revision
+    , hostModule         :: ModuleName
+    , specificationsHome :: FilePath
+    , targetDirectory    :: FilePath
+    , debugParsing       :: Bool
+    }
+
+disableDebugging :: ScaffoldingEnv -> ScaffoldingEnv
+disableDebugging env = env { debugParsing = False }