From c9d13ae319b4f01202a1afad046c3c1add1cc7ba Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Isma=C3=ABl=20Bouya?= <ismael.bouya@normalesup.org>
Date: Tue, 7 May 2019 00:01:09 +0200
Subject: Move dokuwiki to pkgs

---
 pkgs/webapps/dokuwiki/default.nix        | 41 ++++++++++++++++++++++++++++++++
 pkgs/webapps/dokuwiki/dokuwiki.json      | 15 ++++++++++++
 pkgs/webapps/dokuwiki/plugins/farmer.nix | 25 +++++++++++++++++++
 pkgs/webapps/dokuwiki/plugins/todo.nix   | 18 ++++++++++++++
 4 files changed, 99 insertions(+)
 create mode 100644 pkgs/webapps/dokuwiki/default.nix
 create mode 100644 pkgs/webapps/dokuwiki/dokuwiki.json
 create mode 100644 pkgs/webapps/dokuwiki/plugins/farmer.nix
 create mode 100644 pkgs/webapps/dokuwiki/plugins/todo.nix

(limited to 'pkgs/webapps/dokuwiki')

diff --git a/pkgs/webapps/dokuwiki/default.nix b/pkgs/webapps/dokuwiki/default.nix
new file mode 100644
index 0000000..7b5d899
--- /dev/null
+++ b/pkgs/webapps/dokuwiki/default.nix
@@ -0,0 +1,41 @@
+{ varDir ? "/var/lib/dokuwiki", preload ? "", lib, stdenv, mylibs, writeText }:
+let
+  preloadFile = plugins: let preloads = [preload]
+      ++ builtins.concatMap (p: lib.optional (lib.hasAttr "preload" p) (p.preload p)) plugins;
+    in writeText "preload.php" (''
+      <?php
+      '' + builtins.concatStringsSep "\n" preloads
+    );
+  withPlugins = plugins: package.overrideAttrs(old: {
+    name = "${old.name}-with-plugins";
+    installPhase = old.installPhase + (
+      builtins.concatStringsSep "\n" (
+        map (value: "ln -sf ${value} $out/lib/plugins/${value.pluginName}") plugins
+        )
+      );
+    installPreloadPhase = ''
+      cp ${preloadFile plugins} $out/inc/preload.php
+      '';
+    passthru.plugins = plugins;
+    passthru.withPlugins = morePlugins: old.withPlugins (morePlugins ++ plugins);
+  });
+  package = stdenv.mkDerivation (mylibs.fetchedGithub ./dokuwiki.json // rec {
+    phases = "unpackPhase buildPhase installPhase installPreloadPhase fixupPhase";
+    buildPhase = ''
+      mv conf conf.dist
+      mv data data.dist
+    '';
+    installPhase = ''
+      cp -a . $out
+      ln -sf ${varDir}/{conf,data} $out/
+      ln -sf ${varDir}/conf/.htaccess $out/
+    '';
+    installPreloadPhase = ''
+      cp ${preloadFile []} $out/inc/preload.php
+      '';
+    passthru = {
+      plugins = [];
+      inherit withPlugins varDir;
+    };
+  });
+in package
diff --git a/pkgs/webapps/dokuwiki/dokuwiki.json b/pkgs/webapps/dokuwiki/dokuwiki.json
new file mode 100644
index 0000000..fc03252
--- /dev/null
+++ b/pkgs/webapps/dokuwiki/dokuwiki.json
@@ -0,0 +1,15 @@
+{
+  "tag": "release_stable_2018-04-22b",
+  "meta": {
+    "name": "dokuwiki",
+    "url": "https://github.com/splitbrain/dokuwiki",
+    "branch": "refs/tags/release_stable_2018-04-22b"
+  },
+  "github": {
+    "owner": "splitbrain",
+    "repo": "dokuwiki",
+    "rev": "871dae1320b40211626c7ec665f5e6d5290aca95",
+    "sha256": "1syvd5dvv3v75swf8ig7dxqs0g5xikb0f6vlcy7g4c4ghldkw7nz",
+    "fetchSubmodules": true
+  }
+}
diff --git a/pkgs/webapps/dokuwiki/plugins/farmer.nix b/pkgs/webapps/dokuwiki/plugins/farmer.nix
new file mode 100644
index 0000000..b737b2d
--- /dev/null
+++ b/pkgs/webapps/dokuwiki/plugins/farmer.nix
@@ -0,0 +1,25 @@
+{ stdenv, fetchFromGitHub }:
+stdenv.mkDerivation rec {
+  version = "72b8577-master";
+  name = "dokuwiki-plugin-farmer-${version}";
+  src = fetchFromGitHub {
+    owner = "cosmocode";
+    repo = "dokuwiki-plugin-farmer";
+    rev = "72b857734fd164bf79cc6e17abe56491d55c1072";
+    sha256 = "1c9vc1z7yvzjz4p054kshb9yd00a4bb52s43k9zav0lvwvjij9l0";
+  };
+  installPhase = ''
+    mkdir $out
+    cp -a * $out
+    '';
+  passthru = {
+    pluginName = "farmer";
+    preload = out: ''
+      # farm setup by farmer plugin
+      if (file_exists('${out}/DokuWikiFarmCore.php'))
+      {
+        include('${out}/DokuWikiFarmCore.php');
+      }
+    '';
+  };
+}
diff --git a/pkgs/webapps/dokuwiki/plugins/todo.nix b/pkgs/webapps/dokuwiki/plugins/todo.nix
new file mode 100644
index 0000000..a3e03fb
--- /dev/null
+++ b/pkgs/webapps/dokuwiki/plugins/todo.nix
@@ -0,0 +1,18 @@
+{ stdenv, fetchFromGitHub }:
+stdenv.mkDerivation rec {
+  version = "49068ec-master";
+  name = "dokuwiki-plugin-todo-${version}";
+  src = fetchFromGitHub {
+    owner = "leibler";
+    repo = "dokuwiki-plugin-todo";
+    rev = "49068ecea455ea997d1e4a7adab171ccaf8228e8";
+    sha256 = "1jaq623kp14fyhamsas5mk9ryqlk4q6x6znijrb5xhcdg3r83gmq";
+  };
+  installPhase = ''
+    mkdir $out
+    cp -a * $out
+    '';
+  passthru = {
+    pluginName = "todo";
+  };
+}
-- 
cgit v1.2.3