blob: 44f68e8425259e843fcd569e7c467c1ca9cf9e40 (
plain) (
tree)
|
|
pkgname=dwm-git-custom
_pkgname=dwm
pkgver=6.2_029b988
pkgrel=1
pkgdesc="A dynamic window manager for X"
url="http://dwm.suckless.org"
arch=('i686' 'x86_64')
license=('MIT')
options=(zipman)
depends=('libx11' 'libxinerama' 'libxft')
makedepends=('git')
install=dwm.install
provides=('dwm')
conflicts=('dwm')
epoch=1
source=(dwm.desktop
"$_pkgname::git+http://git.suckless.org/dwm")
md5sums=('939f403a71b6e85261d09fc3412269ee'
'SKIP')
pkgver(){
cd $_pkgname
echo $(git describe --tags |sed 's/-/./g')_$(md5sum $SRCDEST/config.h | cut -c1-7)
}
prepare() {
cd $_pkgname
if [[ -f "$SRCDEST/config.h" ]]; then
cp -f "$SRCDEST/config.h" config.h
fi
}
build() {
cd $_pkgname
make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}
package() {
cd $_pkgname
make PREFIX=/usr DESTDIR="$pkgdir" install
install -m644 -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -m644 -D README "$pkgdir/usr/share/doc/$pkgname/README"
install -m644 -D ../dwm.desktop "$pkgdir/usr/share/xsessions/dwm.desktop"
}
# vim:set ts=2 sw=2 et:
|
