pkgs/python-packages/buildbot/plugins/buildslist/default.nix

   1 { mylibs, runCommand, buildBowerComponents, pythonPackages, libsass, python, fetchurl, jq, yarn, nodejs }:
   2 let
   3   buildslist_src = mylibs.fetchedGit ./buildslist.json;
   4   packagejson = runCommand "package.json" { buildInputs = [ jq ]; } ''
   5     cat ${buildslist_src.src}/package.json | jq -r '.version = "${pythonPackages.buildbot-pkg.version}"' > $out
   6     '';
   7   buildslist_yarn = mylibs.yarn2nixPackage.mkYarnModules rec {
   8     name = "buildslist-yarn-modules";
   9     pname = name;
  10     inherit (pythonPackages.buildbot-pkg) version;
  11     packageJSON = packagejson;
  12     yarnLock = "${buildslist_src.src}/yarn.lock";
  13     yarnNix = ./yarn-packages.nix;
  14     pkgConfig = {
  15       all = { buildInputs = [ mylibs.yarn2nixPackage.src ]; };
  16       node-sass = {
  17         buildInputs = [ libsass python ];
  18         postInstall = let
  19           nodeHeaders = fetchurl {
  20             url = "https://nodejs.org/download/release/v${nodejs.version}/node-v${nodejs.version}-headers.tar.gz";
  21             sha256 = "16f20ya3ys6w5w6y6l4536f7jrgk4gz46bf71w1r1xxb26a54m32";
  22           };
  23         in
  24           ''
  25             node scripts/build.js --tarball=${nodeHeaders}
  26           '';
  27       };
  28     };
  29   };
  30   buildslist_bower = buildBowerComponents {
  31     name = "buildslist";
  32     generated = ./bower.nix;
  33     src = "${buildslist_src.src}/guanlecoja/";
  34   };
  35 in
  36 pythonPackages.buildPythonPackage rec {
  37   pname = "buildbot-buildslist";
  38   inherit (pythonPackages.buildbot-pkg) version;
  39
  40   preConfigure = ''
  41     export HOME=$PWD
  42     ln -s ${buildslist_yarn}/node_modules .
  43     cp -a ${buildslist_bower}/bower_components ./libs
  44     chmod -R u+w libs
  45     '';
  46   propagatedBuildInputs = with pythonPackages; [
  47     (klein.overridePythonAttrs(old: { checkPhase = ""; }))
  48     buildbot-pkg
  49   ];
  50   nativeBuildInputs = [ yarn nodejs ];
  51   buildInputs = [ buildslist_yarn buildslist_bower ];
  52
  53   doCheck = false;
  54   src = buildslist_src.src;
  55 }