pkgs/python-packages/buildbot/plugins/buildslist/default.nix

   1 { mylibs, runCommand, buildBowerComponents, pythonPackages, jq, yarn, nodejs }:
   2 let
   3   buildslist_src = mylibs.fetchedGit ./buildslist.json;
   4   packagejson = runCommand "package.json" { buildInputs = [ jq ]; } ''
   5     cat ${buildslist_src.src}/package.json | jq -r '.version = "${pythonPackages.buildbot-pkg.version}"' > $out
   6     '';
   7   buildslist_yarn = mylibs.yarn2nixPackage.mkYarnModules rec {
   8     name = "buildslist-yarn-modules";
   9     pname = name;
  10     inherit (pythonPackages.buildbot-pkg) version;
  11     packageJSON = packagejson;
  12     yarnLock = "${buildslist_src.src}/yarn.lock";
  13     yarnNix = ./yarn-packages.nix;
  14     pkgConfig = {
  15       all = { buildInputs = [ mylibs.yarn2nixPackage.src ]; };
  16     };
  17   };
  18   buildslist_bower = buildBowerComponents {
  19     name = "buildslist";
  20     generated = ./bower.nix;
  21     src = "${buildslist_src.src}/guanlecoja/";
  22   };
  23 in
  24 pythonPackages.buildPythonPackage rec {
  25   pname = "buildbot-buildslist";
  26   inherit (pythonPackages.buildbot-pkg) version;
  27
  28   __noChroot = true;
  29   preConfigure = ''
  30     export HOME=$PWD
  31     cp -a ${buildslist_yarn}/node_modules .
  32     chmod -R u+w node_modules
  33     cp -a ${buildslist_bower}/bower_components ./libs
  34     chmod -R u+w libs
  35     '';
  36   propagatedBuildInputs = with pythonPackages; [
  37     (klein.overridePythonAttrs(old: { checkPhase = ""; }))
  38     buildbot-pkg
  39   ];
  40   nativeBuildInputs = [ yarn nodejs ];
  41   buildInputs = [ buildslist_yarn buildslist_bower ];
  42
  43   doCheck = false;
  44   src = buildslist_src.src;
  45 }