{ lib, env, fetchedGithub, writeText, stdenv, fetchurl }:
rec {
  varDir = "/var/lib/kanboard";
  activationScript = {
    deps = [ "wrappers" ];
    text = ''
      install -m 0755 -o ${apache.user} -g ${apache.group} -d ${varDir}/data
      install -m 0750 -o ${apache.user} -g ${apache.group} -d ${varDir}/phpSessions
      install -TDm644 ${webRoot}/dataold/.htaccess ${varDir}/data/.htaccess
      install -TDm644 ${webRoot}/dataold/web.config ${varDir}/data/web.config
    '';
  };
  config = writeText "config.php" ''
    <?php
    define('MAIL_FROM', 'kanboard@tools.immae.eu');

    define('DB_DRIVER', 'postgres');
    define('DB_USERNAME', '${env.postgresql.user}');
    define('DB_PASSWORD', '${env.postgresql.password}');
    define('DB_HOSTNAME', '${env.postgresql.socket}');
    define('DB_NAME', '${env.postgresql.database}');

    define('LDAP_AUTH', true);
    define('LDAP_SERVER', '${env.ldap.host}');
    define('LDAP_START_TLS', true);

    define('LDAP_BIND_TYPE', 'proxy');
    define('LDAP_USERNAME', '${env.ldap.dn}');
    define('LDAP_PASSWORD', '${env.ldap.password}');
    define('LDAP_USER_BASE_DN', '${env.ldap.base}');
    define('LDAP_USER_FILTER', '(&(memberOf=cn=users,cn=kanboard,ou=services,dc=immae,dc=eu)(uid=%s))');
    define('LDAP_GROUP_ADMIN_DN', 'cn=admins,cn=kanboard,ou=services,dc=immae,dc=eu');
    ?>
    '';
  webRoot = stdenv.mkDerivation (fetchedGithub ./kanboard.json // rec {
    dontBuild = true;
    installPhase = ''
      cp -a . $out
      ln -s ${config} $out/config.php
      mv $out/data $out/dataold
      ln -s ${varDir}/data $out/data
      '';
  });
  apache = rec {
    user = "wwwrun";
    group = "wwwrun";
    modules = [ "proxy_fcgi" ];
    webappName = "tools_kanboard";
    root = "/run/current-system/webapps/${webappName}";
    vhostConf = ''
    Alias /kanboard "${root}"
    <Directory "${root}">
      DirectoryIndex index.php
      AllowOverride All
      Options FollowSymlinks
      Require all granted

      <FilesMatch "\.php$">
        SetHandler "proxy:unix:${phpFpm.socket}|fcgi://localhost"
      </FilesMatch>
    </Directory>
    <DirectoryMatch "${root}/data">
      Require all denied
    </DirectoryMatch>
      '';
  };
  phpFpm = rec {
    basedir = builtins.concatStringsSep ":" [ webRoot varDir config ];
    socket = "/var/run/phpfpm/kanboard.sock";
    pool = ''
      listen = ${socket}
      user = ${apache.user}
      group = ${apache.group}
      listen.owner = ${apache.user}
      listen.group = ${apache.group}
      pm = ondemand
      pm.max_children = 60
      pm.process_idle_timeout = 60

      ; Needed to avoid clashes in browser cookies (same domain)
      php_value[session.name] = KanboardPHPSESSID
      php_admin_value[open_basedir] = "${basedir}:/tmp"
      php_admin_value[session.save_path] = "${varDir}/phpSessions"
      '';
  };
}