{ lib, pkgs, config, myconfig,  ... }:
let
  aten_dev = pkgs.callPackage ./aten.nix {
    inherit (pkgs.webapps) aten;
    config = myconfig.env.websites.aten.integration;
  };
  aten_prod = pkgs.callPackage ./aten.nix {
    inherit (pkgs.webapps) aten;
    config = myconfig.env.websites.aten.production;
  };

  cfg = config.services.myWebsites.Aten;
in {
  options.services.myWebsites.Aten = {
    production = {
      enable = lib.mkEnableOption "enable Aten's website in production";
    };
    integration = {
      enable = lib.mkEnableOption "enable Aten's website in integration";
    };
  };

  config = lib.mkMerge [
    (lib.mkIf cfg.production.enable {
      secrets.keys = aten_prod.keys;
      services.webstats.sites = [ { name = "aten.pro"; } ];

      security.acme.certs."aten" = config.services.myCertificates.certConfig // {
        domain = "aten.pro";
        extraDomains = {
          "www.aten.pro" = null;
        };
      };

      services.myPhpfpm.preStart.aten_prod = aten_prod.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.aten_prod = aten_prod.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.aten_prod = aten_prod.phpFpm.pool;
      system.activationScripts.aten_prod = aten_prod.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${aten_prod.app.webRoot} $out/webapps/${aten_prod.apache.webappName}
        '';
      services.websites.production.modules = aten_prod.apache.modules;
      services.websites.production.vhostConfs.aten = {
        certName    = "aten";
        hosts       = [ "aten.pro" "www.aten.pro" ];
        root        = aten_prod.apache.root;
        extraConfig = [ aten_prod.apache.vhostConf ];
      };
    })
    (lib.mkIf cfg.integration.enable {
      secrets.keys = aten_dev.keys;
      security.acme.certs."eldiron".extraDomains."dev.aten.pro" = null;
      services.myPhpfpm.preStart.aten_dev = aten_dev.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.aten_dev = aten_dev.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.aten_dev = aten_dev.phpFpm.pool;
      system.activationScripts.aten_dev = aten_dev.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${aten_dev.app.webRoot} $out/webapps/${aten_dev.apache.webappName}
        '';
      services.websites.integration.modules = aten_dev.apache.modules;
      services.websites.integration.vhostConfs.aten = {
        certName    = "eldiron";
        hosts       = [ "dev.aten.pro" ];
        root        = aten_dev.apache.root;
        extraConfig = [ aten_dev.apache.vhostConf ];
      };
    })
  ];
}