{ lib, pkgs, config,  ... }:
let
  adminer = pkgs.callPackage ../commons/adminer.nix { inherit config; };
  cfg = config.myServices.websites.telio_tortay.production;
  varDir = "/var/lib/ftp/telio_tortay";
  env = config.myEnv.websites.telio_tortay;
  apacheUser = config.services.httpd.Prod.user;
  apacheGroup = config.services.httpd.Prod.group;
in {
  options.myServices.websites.telio_tortay.production.enable = lib.mkEnableOption "enable Telio Tortay's website";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "telio-tortay.immae.eu"; } ];

    security.acme.certs."ftp".extraDomains."telio-tortay.immae.eu" = null;

    system.activationScripts.telio_tortay = {
      deps = [ "httpd" ];
      text = ''
        install -m 0755 -o ${apacheUser} -g ${apacheGroup} -d /var/lib/ftp/telio_tortay/logs
        install -m 0755 -o ${apacheUser} -g ${apacheGroup} -d /var/lib/php/sessions/telio_tortay
        '';
    };
    systemd.services.phpfpm-telio_tortay.after = lib.mkAfter [ "mysql.service" ];
    systemd.services.phpfpm-telio_tortay.wants = [ "mysql.service" ];
    services.phpfpm.pools.telio_tortay = {
      user = apacheUser;
      group = apacheGroup;
      settings = {
        "listen.owner" = apacheUser;
        "listen.group" = apacheGroup;

        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";

        "php_admin_value[open_basedir]" = "/var/lib/php/sessions/telio_tortay:${varDir}:/tmp";
        "php_admin_value[session.save_path]" = "/var/lib/php/sessions/telio_tortay";
      };
      phpOptions = config.services.phpfpm.phpOptions + ''
        disable_functions = "mail"
      '';
      phpPackage = pkgs.php72;
    };
    services.websites.env.production.modules = adminer.apache.modules ++ [ "proxy_fcgi" ];
    services.websites.env.production.vhostConfs.telio_tortay = {
      certName     = "telio_tortay";
      certMainHost = "telio-tortay.immae.eu";
      hosts        = ["telio-tortay.immae.eu" "realistesmedia.fr" "www.realistesmedia.fr" ];
      root         = varDir;
      extraConfig  = [
        (adminer.apache.vhostConf null)
        ''
        Use Stats telio-tortay.immae.eu
        ServerAdmin ${env.server_admin}
        ErrorLog "${varDir}/logs/error_log"
        CustomLog "${varDir}/logs/access_log" combined

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.telio_tortay.socket}|fcgi://localhost"
        </FilesMatch>

        <Location /xmlrpc.php>
          AllowOverride None
          Require all denied
        </Location>
        <Directory ${varDir}/logs>
          AllowOverride None
          Require all denied
        </Directory>
        <Directory ${varDir}>
          DirectoryIndex index.php index.htm index.html
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride all
          Require all granted
        </Directory>
          ''
      ];
    };
  };
}