{ lib, pkgs, config,  myconfig, ... }:
let
  secrets = myconfig.env.websites.connexionswing.production;
  app = pkgs.webapps.connexionswing.override { environment = secrets.environment; };
  cfg = config.myServices.websites.connexionswing.production;
  pcfg = config.services.phpApplication;
in {
  options.myServices.websites.connexionswing.production.enable = lib.mkEnableOption "enable Connexionswing's website in production";

  config = lib.mkIf cfg.enable {
    services.duplyBackup.profiles.connexionswing_prod.rootDir = app.varDir;
    services.webstats.sites = [ { name = "connexionswing.com"; } ];
    services.phpApplication.apps.connexionswing_prod = {
      websiteEnv = "production";
      httpdUser = config.services.httpd.Prod.user;
      httpdGroup = config.services.httpd.Prod.group;
      inherit (app) webRoot varDir;
      varDirPaths = {
        "medias" = "0700";
        "uploads" = "0700";
        "var" = "0700";
      };
      inherit app;
      serviceDeps = [ "mysql.service" ];
      preStartActions = [
        "./bin/console --env=${app.environment} cache:clear --no-warmup"
      ];
      phpOpenbasedir = [ "/tmp" "/run/wrappers/bin/sendmail" ];
      phpPool = ''
        php_admin_value[upload_max_filesize] = 20M
        php_admin_value[post_max_size] = 20M
        ;php_admin_flag[log_errors] = on
        pm = dynamic
        pm.max_children = 20
        pm.start_servers = 2
        pm.min_spare_servers = 1
        pm.max_spare_servers = 3
      '';
      phpWatchFiles = [
        config.secrets.fullPaths."webapps/${app.environment}-connexionswing"
      ];
    };

    secrets.keys = [
      {
        dest = "webapps/${app.environment}-connexionswing";
        user = config.services.httpd.Prod.user;
        group = config.services.httpd.Prod.group;
        permissions = "0400";
        text = ''
          # This file is auto-generated during the composer install
          parameters:
              database_host: ${secrets.mysql.host}
              database_port: ${secrets.mysql.port}
              database_name: ${secrets.mysql.name}
              database_user: ${secrets.mysql.user}
              database_password: ${secrets.mysql.password}
              database_server_version: ${pkgs.mariadb.mysqlVersion}
              mailer_transport: sendmail
              mailer_host: null
              mailer_user: null
              mailer_password: null
              subscription_email: ${secrets.email}
              allow_robots: true
              secret: ${secrets.secret}
          services:
            swiftmailer.mailer.default.transport:
                class:     Swift_SendmailTransport
                arguments: ['/run/wrappers/bin/sendmail -bs']
        '';
      }
    ];

    services.websites.env.production.vhostConfs.connexionswing_prod = {
      certName     = "connexionswing";
      certMainHost = "connexionswing.com";
      hosts        = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
      root         = pcfg.webappDirs.connexionswing_prod;
      extraConfig  = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${pcfg.phpListenPaths.connexionswing_prod}|fcgi://localhost"
        </FilesMatch>

        <Directory ${app.varDir}/medias>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        <Directory ${app.varDir}/uploads>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        Use Stats connexionswing.com

        <Directory ${pcfg.webappDirs.connexionswing_prod}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}