{ environment ? "prod"
, varDir ? "/var/lib/connexionswing_${environment}"
, secretsPath ? "/var/secrets/webapps/${environment}-connexionswing"
, composerEnv, fetchurl, fetchgit, sources }:
let
  app = composerEnv.buildPackage (
    import ./php-packages.nix { inherit composerEnv fetchurl fetchgit; } //
    rec {
      pname = "connexionswing";
      name = "${pname}-${version}";
      version = sources.websites-connexionswing-app.version;
      src = sources.websites-connexionswing-app;
      noDev = (environment == "prod");
      preInstall = ''
          export SYMFONY_ENV="${environment}"
      '';
      postInstall = ''
          cd $out
          ${if environment == "prod" then "php ./bin/console assetic:dump --env=prod --no-debug" else ""}
          rm app/config/parameters.yml
          ln -sf ${secretsPath} app/config/parameters.yml
          rm -rf var/{logs,cache}
          ln -sf ${varDir}/var/{logs,cache} var/
          ln -sf ${varDir}/{medias,uploads} web/images/
      '';
      passthru = {
        inherit varDir environment;
        webRoot = "${app}/web";
      };
    });
in app