{ lib, pkgs, config, myconfig,  ... }:
let
  chloe = pkgs.callPackage ./builder.nix {
    inherit (pkgs.webapps) chloe;
    config = myconfig.env.websites.chloe.production;
    apacheUser = config.services.httpd.Prod.user;
    apacheGroup = config.services.httpd.Prod.group;
  };

  cfg = config.myServices.websites.chloe.production;
in {
  options.myServices.websites.chloe.production.enable = lib.mkEnableOption "enable Chloe's website in production";

  config = lib.mkIf cfg.enable {
    secrets.keys = chloe.keys;
    services.webstats.sites = [ { name = "osteopathe-cc.fr"; } ];

    systemd.services.phpfpm-chloe_prod.after = lib.mkAfter chloe.phpFpm.serviceDeps;
    systemd.services.phpfpm-chloe_prod.wants = chloe.phpFpm.serviceDeps;
    services.phpfpm.pools.chloe_prod = {
      listen = chloe.phpFpm.socket;
      extraConfig = chloe.phpFpm.pool;
      phpOptions = config.services.phpfpm.phpOptions + ''
        extension=${pkgs.php}/lib/php/extensions/mysqli.so
      '';
    };
    system.activationScripts.chloe_prod = chloe.activationScript;
    system.extraSystemBuilderCmds = ''
      mkdir -p $out/webapps
      ln -s ${chloe.app.webRoot} $out/webapps/${chloe.apache.webappName}
      '';
    services.websites.production.modules = chloe.apache.modules;
    services.websites.production.vhostConfs.chloe = {
      certName     = "chloe";
      certMainHost = "osteopathe-cc.fr";
      hosts        = ["osteopathe-cc.fr" "www.osteopathe-cc.fr" ];
      root         = chloe.apache.root;
      extraConfig  = [ chloe.apache.vhostConf ];
    };
  };
}