{ privateFiles }:
{ config, pkgs, name, lib, ... }:
{
  boot.supportedFilesystems = [ "zfs" ];
  boot.kernelPackages = pkgs.linuxPackages_latest;
  myEnv = import "${privateFiles}/environment.nix" // { inherit privateFiles; };

  fileSystems = {
    "/"           = lib.mkForce { fsType = "zfs"; device = "zpool/root"; };
    "/boot"       = { fsType = "ext4"; device = "/dev/disk/by-uuid/fd1c511e-2bc0-49d5-b8bb-95e7e8c8c816"; };
    "/etc"        = { fsType = "zfs"; device = "zpool/root/etc"; };
    "/home"       = { fsType = "zfs"; device = "zpool/root/home"; };
    "/home/immae" = { fsType = "zfs"; device = "zpool/root/home/immae"; };
    "/tmp"        = { fsType = "zfs"; device = "zpool/root/tmp"; };
    "/var"        = { fsType = "zfs"; device = "zpool/root/var"; };
  };
  boot.initrd.secrets = {
    "/boot/pass.key" = "/boot/pass.key";
  };

  networking = {
    hostId = "27c3048d"; # generated with head -c4 /dev/urandom | od -A none -t x4
    firewall.enable = false;
    interfaces."eth0".ipv4.addresses = pkgs.lib.attrsets.mapAttrsToList
      (n: ips: { address = ips.ip4; prefixLength = 32; })
      (pkgs.lib.attrsets.filterAttrs (n: v: n != "main") config.hostEnv.ips);
    interfaces."eth0".ipv6.addresses = pkgs.lib.flatten (pkgs.lib.attrsets.mapAttrsToList
      (n: ips: map (ip: { address = ip; prefixLength = (if n == "main" && ip == pkgs.lib.head ips.ip6 then 64 else 128); }) (ips.ip6 or []))
      config.hostEnv.ips);
  };

  myServices.ssh.modules = [ config.myServices.ssh.predefinedModules.regular ];
  imports = builtins.attrValues (import ../..);

  deployment = {
    targetEnv = "hetzner";
    hetzner = {
      robotUser = config.myEnv.hetzner.user;
      robotPass = config.myEnv.hetzner.pass;
      mainIPv4 = config.hostEnv.ips.main.ip4;
      partitions = ''
        clearpart --all --initlabel --drives=sda,sdb,sdc,sdd

        part swap --recommended --label=swap --fstype=swap --ondisk=sda

        part raid.1 --grow --ondisk=sdc
        part raid.2 --grow --ondisk=sdd

        raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2

        part /nix --grow --label=nix --ondisk=sda
        part /data --grow --label=data --ondisk=sdb
      '';
    };
  };

  system.nssModules = [ pkgs.libvirt ];
  system.nssDatabases.hosts = lib.mkForce [ "files" "libvirt_guest" "mymachines" "dns" "myhostname" ];
  programs.zsh.enable = true;

  users.users.backup = {
    home = "/var/lib/backup";
    createHome = true;
    hashedPassword = "!";
    isSystemUser = true;
    shell = pkgs.bashInteractive;
    openssh.authorizedKeys.keys = let
    in
      ["command=\"${pkgs.rrsync_sudo}/bin/rrsync /var/lib/backup/eldiron/\"  ${config.myEnv.rsync_backup.ssh_key.public}"];
  };
  security.sudo.extraRules = pkgs.lib.mkAfter [
    {
      commands = [
        { command = "${pkgs.rsync}/bin/rsync"; options = [ "NOPASSWD" ]; }
      ];
      users = [ "backup" ];
      runAs = "root";
    }
    {
      commands = [
        { command = "/home/immae/.nix-profile/root_scripts/*"; options = [ "NOPASSWD" ]; }
      ];
      users = [ "immae" ];
      runAs = "root";
    }
  ];

  boot.kernel.sysctl."vm.nr_hugepages" = 256; # for xmr-stak
  system.activationScripts.backup_home = ''
    chown root:root /var/lib/backup
    install -m 0750 -o backup -g root -d /var/lib/backup/eldiron
  '';

  system.activationScripts.libvirtd_exports = ''
    install -m 0755 -o root -g root -d /var/lib/caldance
  '';
  virtualisation.docker.enable = true;
  virtualisation.docker.storageDriver = "zfs";
  virtualisation.libvirtd.enable = true;
  users.extraUsers.immae.extraGroups = [ "libvirtd" "docker" ];
  systemd.services.libvirtd.postStart = ''
    install -m 0770 -g libvirtd -d /var/lib/libvirt/images
  '';
  systemd.services.socat-caldance = {
    description = "Forward ssh port to caldance";
    wantedBy = [ "multi-user.target" ];
    after = [ "network.target" ];

    serviceConfig = {
      ExecStart = "${pkgs.socat}/bin/socat TCP-LISTEN:8022,fork TCP:nixops-99a7e1ba-54dc-11ea-a965-10bf487fe63b-caldance:22";
    };
  };

  time.timeZone = "Europe/Paris";
  nix = {
    useSandbox = "relaxed";
    extraOptions = ''
      keep-outputs = true
      keep-derivations = true
      #Assumed in NUR
      allow-import-from-derivation = true
    '';
  };

  security.pki.certificateFiles = [
    (pkgs.fetchurl {
      url = "http://downloads.e.eriomem.net/eriomemca.pem";
      sha256 = "1ixx4c6j3m26j8dp9a3dkvxc80v1nr5aqgmawwgs06bskasqkvvh";
    })
  ];

  # This is equivalent to setting environment.sessionVariables.NIX_PATH
  nix.nixPath = [
    "home-manager=${pkgs.sources.home-manager.url}"
    "nixpkgs=${pkgs.sources.nixpkgs-home-manager.url}"
  ];
  nix.binaryCaches = [ "https://hydra.iohk.io" "https://cache.nixos.org" ];
  nix.binaryCachePublicKeys = [ "hydra.iohk.io:f/Ea+s+dFdN+3Y/G+FDgSq+a5NEWhJGzdjvKNGv0/EQ=" ];

  myServices.certificates.enable = true;
  security.acme.certs."${name}" = {
    user = config.services.nginx.user;
    group = config.services.nginx.group;
    extraDomains = {
      "discourse.immae.eu" = null;
      "discourse.cip-ca.fr" = null;
      "dev.immae.eu" = null;
      "caldance.immae.eu" = null;
    };
  };
  services.nginx = {
    enable = true;
    recommendedOptimisation = true;
    recommendedGzipSettings = true;
    recommendedProxySettings = true;
    upstreams = {
      caldance.servers."nixops-99a7e1ba-54dc-11ea-a965-10bf487fe63b-caldance:3031" = {};
    };
    virtualHosts = {
      "dev.immae.eu" = {
        acmeRoot = config.myServices.certificates.webroot;
        useACMEHost = name;
        forceSSL = true;
        root = "/home/immae/www";
      };
      "discourse.immae.eu" = {
        acmeRoot = config.myServices.certificates.webroot;
        useACMEHost = name;
        forceSSL = true;
        locations."/".proxyPass = "http://localhost:18031";
      };
      "discourse.cip-ca.fr" = {
        acmeRoot = config.myServices.certificates.webroot;
        useACMEHost = name;
        forceSSL = true;
        locations."/".proxyPass = "http://localhost:18031";
      };
      "caldance.immae.eu" = {
        acmeRoot = config.myServices.certificates.webroot;
        useACMEHost = name;
        forceSSL = true;
        locations."/".extraConfig = ''
          uwsgi_pass caldance;
        '';
        locations."/static/".alias = "/var/lib/caldance/caldance/app/www/static/";
        locations."/media/".alias = "/var/lib/caldance/caldance/media/";
        extraConfig = ''
          auth_basic           "Authentification requise";
          auth_basic_user_file ${pkgs.writeText "htpasswd" config.myEnv.websites.caldance.integration.password};
        '';
      };
    };
  };

  # This value determines the NixOS release with which your system is
  # to be compatible, in order to avoid breaking some software such as
  # database servers. You should change this only after NixOS release
  # notes say you should.
  # https://nixos.org/nixos/manual/release-notes.html
  system.stateVersion = "20.03"; # Did you read the comment?
}