{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.piedsjaloux.integration;
  cfg = config.myServices.websites.piedsjaloux.integration;
  texlive = pkgs.texlive.combine { inherit (pkgs.texlive) attachfile preprint scheme-small; };
  ftpRoot = "/var/lib/piedsjaloux_integration";
  phpRoot = "${ftpRoot}/php";
  webRoot = "${phpRoot}/web";
  varDir = "${ftpRoot}/var";
  sessionDir = "${ftpRoot}/sessions";
  packagePath = "/var/lib/ftp/release.immae.eu/buildbot/Piedsjaloux";
  branch = "test";
in {
  options.myServices.websites.piedsjaloux.integration.enable = lib.mkEnableOption "enable PiedsJaloux's website in integration";

  config = lib.mkIf cfg.enable {
    services.phpfpm.pools.piedsjaloux_integration = {
      user = config.services.httpd.Inte.user;
      group = config.services.httpd.Inte.group;
      settings = {
        "listen.owner" = config.services.httpd.Inte.user;
        "listen.group" = config.services.httpd.Inte.group;
        "php_admin_value[open_basedir]" = builtins.concatStringsSep ":" [
          ftpRoot
          config.secrets.fullPaths."websites/piedsjaloux/integration"
          "/tmp"
        ];
        "php_admin_value[session.save_path]" = sessionDir;
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";
      };
      phpEnv = {
        SYMFONY_DEBUG_MODE = "\"yes\"";
      };
      phpPackage = pkgs.php74;
    };
    systemd.services."phpfpm-piedsjaloux_integration" = {
      after = lib.mkAfter ["mysql.service"];
      wants = ["mysql.service"];
      path = lib.mkAfter [ pkgs.gnutar pkgs.gzip pkgs.php74 ];
      preStart = let
        script = pkgs.writeScriptBin "piedsjaloux-integration-pre" ''
          #! ${pkgs.stdenv.shell}

          [ -f ${packagePath}/${branch}.tar.gz ] || exit 1

          cd ${ftpRoot}
          if ! [ -f .tarball_sum ] || ! sha256sum -c .tarball_sum; then
            tar -xf ${packagePath}/${branch}.tar.gz --one-top-level=php_new
            if [ -d php ]; then
              mv php php_old
            fi
            mv php_new php
          fi
          cd php
          rm -rf var/{logs,cache,data,miniatures,tmp}
          ln -sf ${varDir}/{logs,cache,data,miniatures,tmp} var/
          ln -sf ${config.secrets.fullPaths."websites/piedsjaloux/integration"} app/config/parameters.yml
          SYMFONY_ENV=dev ./bin/console --env=dev cache:clear --no-warmup
          sha256sum ${packagePath}/${branch}.tar.gz > ${ftpRoot}/.tarball_sum
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Inte.user} ${script}/bin/piedsjaloux-integration-pre";
      postStart = let
        script = pkgs.writeScriptBin "piedsjaloux-integration-post" ''
          #! ${pkgs.stdenv.shell}

          cd ${ftpRoot}
          if [ -d php_old ]; then
            rm -rf php_old
          fi
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Inte.user} ${script}/bin/piedsjaloux-integration-post";
      serviceConfig.TimeoutStartSec="infinity";
    };
    services.filesWatcher.phpfpm-piedsjaloux_integration = {
      restart = true;
      paths = [ "${packagePath}/${branch}.tar.gz" ];
    };

    system.activationScripts.piedsjaloux_integration = {
      deps = ["users"];
      text = ''
        install -m 0700 -o ${config.services.httpd.Inte.user} -g ${config.services.httpd.Inte.group} -d ${ftpRoot} ${sessionDir}
      '';
    };

    secrets.keys."websites/piedsjaloux/integration" = {
      user = config.services.httpd.Inte.user;
      group = config.services.httpd.Inte.group;
      permissions = "0400";
      text = ''
        # This file is auto-generated during the composer install
        parameters:
            database_host: ${secrets.mysql.host}
            database_port: ${secrets.mysql.port}
            database_name: ${secrets.mysql.database}
            database_user: ${secrets.mysql.user}
            database_password: ${secrets.mysql.password}
            database_server_version: ${pkgs.mariadb.mysqlVersion}
            mailer_transport: smtp
            mailer_host: 127.0.0.1
            mailer_user: null
            mailer_password: null
            secret: ${secrets.secret}
            pdflatex: "${texlive}/bin/pdflatex"
        leapt_im:
            binary_path: ${pkgs.imagemagick}/bin
      '';
    };

    services.websites.env.integration.vhostConfs.piedsjaloux_integration = {
      certName     = "integration";
      addToCerts  = true;
      hosts       = [ "test.pj.immae.dev" ];
      root        = webRoot;
      extraConfig = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.piedsjaloux_integration.socket}|fcgi://localhost"
        </FilesMatch>

        <Location />
          Use LDAPConnect
          Require ldap-group   cn=pj.immae.dev,cn=httpd,ou=services,dc=immae,dc=eu
          ErrorDocument 401 "<html><meta http-equiv=\"refresh\" content=\"0;url=https://piedsjaloux.fr\"></html>"
        </Location>

        <Directory ${webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride None
          Require all granted

          DirectoryIndex app_dev.php

          <IfModule mod_negotiation.c>
          Options -MultiViews
          </IfModule>

          <IfModule mod_rewrite.c>
            RewriteEngine On

            RewriteCond %{REQUEST_URI}::$1 ^(/.+)/(.*)::\2$
            RewriteRule ^(.*) - [E=BASE:%1]

            # Maintenance script
            RewriteCond %{DOCUMENT_ROOT}/maintenance.php -f
            RewriteCond %{SCRIPT_FILENAME} !maintenance.php
            RewriteRule ^.*$ %{ENV:BASE}/maintenance.php [R=503,L]
            ErrorDocument 503 /maintenance.php

            # Sets the HTTP_AUTHORIZATION header removed by Apache
            RewriteCond %{HTTP:Authorization} .
            RewriteRule ^ - [E=HTTP_AUTHORIZATION:%{HTTP:Authorization}]

            RewriteCond %{ENV:REDIRECT_STATUS} ^$
            RewriteRule ^app_dev\.php(?:/(.*)|$) %{ENV:BASE}/$1 [R=301,L]

            # If the requested filename exists, simply serve it.
            # We only want to let Apache serve files and not directories.
            RewriteCond %{REQUEST_FILENAME} -f
            RewriteRule ^ - [L]

            # Rewrite all other queries to the front controller.
            RewriteRule ^ %{ENV:BASE}/app_dev.php [L]
          </IfModule>

        </Directory>
        ''
      ];
    };
  };
}