{ varDir
, secretsPath
, composerEnv, fetchFromGitHub, fetchurl, fetchgit }:
let
  app = composerEnv.buildPackage (
    import ./php-packages.nix { inherit composerEnv fetchurl fetchgit; } //
    rec {
      version = "1.32.3";
      pname = "gestion-compte";
      name = "${pname}-${version}";
      src = fetchFromGitHub {
        owner = "elefan-grenoble";
        repo = "gestion-compte";
        rev = "v${version}";
        sha256 = "16pwp4pqdf85ziryzvcj9ryk9jlz56ja07p8kj7pldghnk9pmkwm";
      };
      noDev = true;
      preInstall = ''
        sed -i -e "/^    charset: utf8mb4/a\    server_version: '%database_version%'" app/config/config.yml
        sed -i -e "/database_password: /a\    database_version: 5.5" app/config/parameters.yml.dist
        export APP_ENV="prod"
        export SYMFONY_ENV="prod"
      '';
      postInstall = ''
        cd $out
        patchShebangs bin/console
        ./bin/console assetic:dump
        rm -rf var
        ln -sf ${varDir} var
        rm -f app/config/parameters.yml
        ln -sf ${secretsPath} app/config/parameters.yml
      '';
      passthru = {
        inherit varDir secretsPath;
        webRoot = "${app}/web";
      };
    }
  );
in app