{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.ludivine.production;
  cfg = config.myServices.websites.ludivine.production;
  ftpRoot = "/var/lib/ludivine_production";
  phpRoot = "${ftpRoot}/php";
  webRoot = "${phpRoot}/web";
  varDir = "${ftpRoot}/var";
  sessionDir = "${ftpRoot}/sessions";
  packagePath = "/var/lib/ftp/release.immae.eu/buildbot/Ludivine";
  branch = "master";
in {
  options.myServices.websites.ludivine.production.enable = lib.mkEnableOption "enable Ludivine's website in production";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "ludivinecassal.com"; } ];
    services.phpfpm.pools.ludivine_production = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      settings = {
        "listen.owner" = config.services.httpd.Prod.user;
        "listen.group" = config.services.httpd.Prod.group;
        "php_admin_value[open_basedir]" = builtins.concatStringsSep ":" [
          ftpRoot
          config.secrets.fullPaths."websites/ludivine/production"
          "/tmp"
        ];
        "php_admin_value[session.save_path]" = sessionDir;
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpPackage = pkgs.php72;
    };
    systemd.services."phpfpm-ludivine_production" = {
      after = lib.mkAfter ["mysql.service"];
      wants = ["mysql.service"];
      path = lib.mkAfter [ pkgs.gnutar pkgs.gzip pkgs.php72 ];
      preStart = let
        script = pkgs.writeScriptBin "ludivine-production-pre" ''
          #! ${pkgs.stdenv.shell}

          [ -f ${packagePath}/${branch}.tar.gz ] || exit 1

          cd ${ftpRoot}
          if ! [ -f .tarball_sum ] || ! sha256sum -c .tarball_sum; then
            tar -xf ${packagePath}/${branch}.tar.gz --one-top-level=php_new
            if [ -d php ]; then
              mv php php_old
            fi
            mv php_new php
          fi
          cd php
          rm -rf var/{logs,cache,data,miniatures,tmp}
          ln -sf ${varDir}/{logs,cache,data,miniatures,tmp} var/
          ln -sf ${config.secrets.fullPaths."websites/ludivine/production"} app/config/parameters.yml
          ./bin/console --env=${secrets.environment} cache:clear --no-warmup
          sha256sum ${packagePath}/${branch}.tar.gz > ${ftpRoot}/.tarball_sum
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/ludivine-production-pre";
      postStart = let
        script = pkgs.writeScriptBin "ludivine-production-post" ''
          #! ${pkgs.stdenv.shell}

          cd ${ftpRoot}
          if [ -d php_old ]; then
            rm -rf php_old
          fi
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/ludivine-production-post";
      serviceConfig.TimeoutStartSec="infinity";
    };
    services.filesWatcher.phpfpm-ludivine_production = {
      restart = true;
      paths = [ "${packagePath}/${branch}.tar.gz" ];
    };

    system.activationScripts.ludivine_production = {
      deps = [];
      text = ''
        install -m 0700 -o ${config.services.httpd.Prod.user} -g ${config.services.httpd.Prod.group} -d ${ftpRoot} ${sessionDir}
      '';
    };

    secrets.keys."websites/ludivine/production" = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      permissions = "0400";
      text = ''
        # This file is auto-generated during the composer install
        parameters:
            database_host: ${secrets.mysql.host}
            database_port: ${secrets.mysql.port}
            database_name: ${secrets.mysql.database}
            database_user: ${secrets.mysql.user}
            database_password: ${secrets.mysql.password}
            database_server_version: ${pkgs.mariadb.mysqlVersion}
            mailer_transport: smtp
            mailer_host: 127.0.0.1
            mailer_user: null
            mailer_password: null
            secret: ${secrets.secret}
            ldap_host: ldap.immae.eu
            ldap_port: 636
            ldap_version: 3
            ldap_ssl: true
            ldap_tls: false
            ldap_user_bind: 'uid={username},ou=users,dc=immae,dc=eu'
            ldap_base_dn: 'dc=immae,dc=eu'
            ldap_search_dn: '${secrets.ldap.dn}'
            ldap_search_password: '${secrets.ldap.password}'
            ldap_search_filter: '${secrets.ldap.filter}'
        leapt_im:
            binary_path: ${pkgs.imagemagick}/bin
        assetic:
            sass: ${pkgs.sass}/bin/sass
            ruby: ${pkgs.ruby}/bin/ruby
      '';
    };

    services.websites.env.production.vhostConfs.ludivine_production = {
      certName     = "ludivine";
      certMainHost = "ludivinecassal.com";
      hosts        = ["ludivinecassal.com" "www.ludivinecassal.com" ];
      root         = webRoot;
      extraConfig  = [
        ''
        RewriteEngine on
        RewriteCond "%{HTTP_HOST}" "!^ludivinecassal\.com$" [NC]
        RewriteRule ^(.+)$ https://ludivinecassal.com$1 [R=302,L]

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.ludivine_production.socket}|fcgi://localhost"
        </FilesMatch>

        Use Stats ludivinecassal.com

        <Directory ${webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}