{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.isabelle.aten_production;
  cfg = config.myServices.websites.isabelle.aten_production;
  ftpRoot = "/var/lib/isabelle_aten_production";
  phpRoot = "${ftpRoot}/php";
  webRoot = "${phpRoot}/public";
  varDir = "${ftpRoot}/var";
  packagePath = "/var/lib/ftp/release.immae.eu/buildbot/IsabelleAten";
  branch = "master";
in {
  options.myServices.websites.isabelle.aten_production.enable = lib.mkEnableOption "enable Aten's website in production";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "aten.pro"; } ];
    services.phpfpm.pools.isabelle_aten_production = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      settings = {
        "listen.owner" = config.services.httpd.Prod.user;
        "listen.group" = config.services.httpd.Prod.group;
        "php_admin_value[open_basedir]" = builtins.concatStringsSep ":" [
          ftpRoot
          config.secrets.fullPaths."websites/isabelle/aten_production"
          "/tmp"
        ];
        "php_admin_value[session.save_handler]" = "redis";
        "php_admin_value[session.save_path]" = "'unix:///run/redis-php-sessions/redis.sock?persistent=1&prefix=Isabelle:AtenProduction:'";
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpPackage = pkgs.php72.withExtensions ({ enabled, all }: enabled ++ [all.redis]);
    };
    systemd.services."phpfpm-isabelle_aten_production" = {
      after = lib.mkAfter ["postgresql.service"];
      wants = ["postgresql.service"];
      path = lib.mkAfter [ pkgs.gnutar pkgs.gzip pkgs.php72 ];
      preStart = let
        script = pkgs.writeScriptBin "isabelle-aten-production" ''
          #! ${pkgs.stdenv.shell}

          [ -f ${packagePath}/${branch}.tar.gz ] || exit 1

          cd ${ftpRoot}
          if ! [ -f .tarball_sum ] || ! sha256sum -c .tarball_sum; then
            tar -xf ${packagePath}/${branch}.tar.gz --one-top-level=php_new
            if [ -d php ]; then
              mv php php_old
            fi
            mv php_new php
          fi
          cd php
          rm -rf var/{log,cache}
          ln -sf ${varDir}/{log,cache} var/
          APP_ENV=${secrets.environment} ./bin/console --env=${secrets.environment} cache:clear --no-warmup
          sha256sum ${packagePath}/${branch}.tar.gz > ${ftpRoot}/.tarball_sum
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/isabelle-aten-production";
      postStart = let
        script = pkgs.writeScriptBin "isabelle-aten-production-post" ''
          #! ${pkgs.stdenv.shell}

          cd ${ftpRoot}
          if [ -d php_old ]; then
            rm -rf php_old
          fi
        '';
      in
        "/run/wrappers/bin/sudo -u ${config.services.httpd.Prod.user} ${script}/bin/isabelle-aten-production-post";
      serviceConfig.TimeoutStartSec="infinity";
    };
    services.filesWatcher.phpfpm-isabelle_aten_production = {
      restart = true;
      paths = [ "${packagePath}/${branch}.tar.gz" ];
    };

    system.activationScripts.isabelle_aten_production = {
      deps = ["users"];
      text = ''
        install -m 0700 -o ${config.services.httpd.Prod.user} -g ${config.services.httpd.Prod.group} -d ${ftpRoot}
      '';
    };

    secrets.keys."websites/isabelle/aten_production" = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      permissions = "0400";
      text = let
        # cf:
        #   https://secure.php.net/manual/fr/function.parse-url.php
        #   vendor/doctrine/dbal/lib/Doctrine/DBAL/DriverManager.php#parseDatabaseUrlQuery
        psql_url = with secrets.postgresql; "pdo-pgsql://${user}:${password}@invalid:${port}/${database}?host=${socket}";
      in ''
        SetEnv APP_ENV      "${secrets.environment}"
        SetEnv APP_SECRET   "${secrets.secret}"
        SetEnv DATABASE_URL "${psql_url}"
        '';
    };
    services.websites.env.production.vhostConfs.isabelle_aten_production = {
      certName     = "isabelle";
      certMainHost = "aten.pro";
      hosts       = [ "aten.pro" "www.aten.pro" ];
      root        = webRoot;
      extraConfig = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.isabelle_aten_production.socket}|fcgi://localhost"
        </FilesMatch>

        Include ${config.secrets.fullPaths."websites/isabelle/aten_production"}

        Use Stats aten.pro

        <Location /backend>
          Use LDAPConnect
          Require ldap-group   cn=aten.pro,cn=httpd,ou=services,dc=immae,dc=eu
          ErrorDocument 401 "<html><meta http-equiv=\"refresh\" content=\"0;url=https://aten.pro\"></html>"
        </Location>

        <Directory ${webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
          DirectoryIndex index.php
          FallbackResource /index.php
        </Directory>
        ''
      ];
    };
  };
}