{ lib, config, pkgs, ... }:
let
  cfg = config.myServices.websites.attilax.dolibarr;
  varDir = "/var/lib/ftp/attilax/dolibarr";
  apacheUser = config.services.httpd.Prod.user;
  apacheGroup = config.services.httpd.Prod.group;
in {
  options.myServices.websites.attilax.dolibarr.enable = lib.mkEnableOption "enable Dolibarr website";

  config = lib.mkIf cfg.enable {
    services.phpfpm.pools.attilax_dolibarr = {
      user = apacheUser;
      group = apacheGroup;
      settings = {
        "listen.owner" = apacheUser;
        "listen.group" = apacheGroup;

        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";

        "php_admin_value[upload_max_filesize]" = "100M";
        "php_admin_value[post_max_size]" = "100M";
        "php_admin_value[open_basedir]" = "${varDir}:/tmp";
        "php_admin_value[session.save_handler]" = "redis";
        "php_admin_value[session.save_path]" = "'unix:///run/redis-php-sessions/redis.sock?persistent=1&prefix=Attilax:Dolibarr:'";
      };
      phpOptions = config.services.phpfpm.phpOptions + ''
        disable_functions = "mail"
      '';
      phpPackage = pkgs.php74.withExtensions ({ enabled, all }: enabled ++ [all.redis]);
    };
    services.websites.env.production.modules = [ "proxy_fcgi" ];
    services.websites.env.production.vhostConfs.attilax_dolibarr = {
      certName     = "attilax";
      addToCerts   = true;
      certMainHost = "doli.attilax.fr";
      hosts        = ["doli.attilax.fr"];
      root         = "${varDir}/dolibarr/htdocs";
      extraConfig  = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.attilax_dolibarr.socket}|fcgi://localhost"
        </FilesMatch>

        <Directory ${varDir}/dolibarr/htdocs>
          DirectoryIndex index.php index.htm index.html
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
          ''
      ];
    };
  };
}