{ pkgs, config, lib, ... }:
{
  config = let
    serverSpecificConfig = config.myEnv.serverSpecific.quatresaisons;
    phpLdapAdmin = pkgs.webapps.phpldapadmin.override { config = config.secrets.fullPaths."webapps/tools-ldap"; };
  in {
    services.postgresql.enable = true;
    services.postgresql.package = pkgs.postgresql_12;
    services.postgresql.ensureUsers = [
      { name = "naemon"; }
    ];
    secrets.keys = {
      "ldap/password" = {
        permissions = "0400";
        user = "openldap";
        group = "openldap";
        text = "${serverSpecificConfig.ldap_root_pw}";
      };
      "webapps/tools-ldap" = {
        user = "wwwrun";
        group = "wwwrun";
        permissions = "0400";
        text = ''
          <?php
          $config->custom->appearance['show_clear_password'] = true;
          $config->custom->appearance['hide_template_warning'] = true;
          $config->custom->appearance['theme'] = "tango";
          $config->custom->appearance['minimalMode'] = false;
          $config->custom->appearance['tree'] = 'AJAXTree';

          $servers = new Datastore();

          $servers->newServer('ldap_pla');
          $servers->setValue('server','name','LDAP');
          $servers->setValue('server','host','ldap://localhost');
          $servers->setValue('login','auth_type','cookie');
          $servers->setValue('login','bind_id','${serverSpecificConfig.ldap_phpldapadmin_dn}');
          $servers->setValue('login','bind_pass','${serverSpecificConfig.ldap_phpldapadmin_password}');
          $servers->setValue('appearance','pla_password_hash','ssha');
          $servers->setValue('login','attr','uid');
          $servers->setValue('login','fallback_dn',true);
        '';
      };
    };

    users.users.openldap.extraGroups = [ "keys" ];
    services.openldap = {
      enable = true;
      urlList = [ "ldap://localhost" ];
      settings = {
        attrs = {
          olcPidFile = "/run/slapd/slapd.pid";
          olcArgsFile = "/run/slapd/slapd.args";
          olcLogLevel = "none";
        };
        children = {
          "cn=module{0}" = {
            attrs = {
              cn = "module{0}";
              objectClass = [ "olcModuleList" ];
              olcModuleLoad = [ "{0}back_hdb" "{1}memberof" "{2}syncprov" ];
            };
          };
          "cn=schema".includes = map (schema:
            "${config.services.openldap.package}/etc/schema/${schema}.ldif"
          ) [ "core" "cosine" "inetorgperson" "nis" ];
          "olcDatabase={0}config" = {
            attrs = {
              objectClass = "olcDatabaseConfig";
              olcDatabase = "{0}config";
              olcAccess = ["{0}to *  by * none"];
            };
          };
          "olcDatabase={1}hdb" = {
            attrs = {
              objectClass = [ "olcDatabaseConfig" "olcHdbConfig" ];
              olcDatabase = "{1}hdb";
              olcAccess = let
                join = builtins.replaceStrings ["\n"] [" "];
              in [
                (join ''{0}to attrs=description
                      by * none
                '')
                (join ''{1}to filter="(uid=*)" attrs=entry,uid
                      by dn.exact="${serverSpecificConfig.ldap_phpldapadmin_dn}" read
                      by * break
                '')
                (join ''{2}to dn.subtree="ou=users,dc=salle-s,dc=org"
                      by dn.subtree="ou=services,dc=salle-s,dc=org" read
                      by * break
                '')
                (join ''{3}to *
                      by self read
                      by anonymous auth
                      by * break
                '')
              ];
              olcDbIndex = [
                "objectClass  eq"
                "uid          pres,eq"
                #"uidMember pres,eq"
                "mail         pres,eq,sub"
                "cn           pres,eq,sub"
                "sn           pres,eq,sub"
                "dc           eq"
                "member       eq"
                "memberOf     eq"
              ];
              olcDbDirectory = "/var/lib/openldap";
              olcRootDN = "cn=root,dc=salle-s,dc=org";
              olcRootPW.path = config.secrets.fullPaths."ldap/password";
              olcSuffix = "dc=salle-s,dc=org";
            };
            children = {
              "olcOverlay={0}memberof" = {
                attrs = {
                  objectClass = [ "olcOverlayConfig" "olcMemberOf" ];
                  olcOverlay = "{0}memberof";
                };
              };
              "olcOverlay={1}syncprov" = {
                attrs = {
                  objectClass = [ "olcOverlayConfig" "olcSyncProvConfig" ];
                  olcOverlay = "{1}syncprov";
                  olcSpCheckpoint = "100 10";
                };
              };
            };
          };
        };
      };
    };

    services.websites.env.production.modules = [ "proxy_fcgi" ];
    services.websites.env.production.vhostConfs.tools.extraConfig = [
      ''
        Alias /ldap "${phpLdapAdmin}/htdocs"
        <Directory "${phpLdapAdmin}/htdocs">
          DirectoryIndex index.php
          <FilesMatch "\.php$">
            SetHandler "proxy:unix:${config.services.phpfpm.pools.ldap.socket}|fcgi://localhost"
          </FilesMatch>

          AllowOverride None
          Require all granted
        </Directory>
      ''
    ];
    services.phpfpm.pools.ldap = {
      user = "wwwrun";
      group = "wwwrun";
      settings =
        let
          basedir = builtins.concatStringsSep ":" [ phpLdapAdmin config.secrets.fullPaths."webapps/tools-ldap" ];
        in {
          "listen.owner" = "wwwrun";
          "listen.group" = "wwwrun";
          "pm" = "ondemand";
          "pm.max_children" = "60";
          "pm.process_idle_timeout" = "60";

          # Needed to avoid clashes in browser cookies (same domain)
          "php_value[session.name]" = "LdapPHPSESSID";
          "php_admin_value[open_basedir]" = "${basedir}:/tmp:/var/lib/php/sessions/phpldapadmin";
          "php_admin_value[session.save_path]" = "/var/lib/php/sessions/phpldapadmin";
        };
      phpPackage = pkgs.php72;
    };
    system.activationScripts.ldap = {
      deps = [ "users" ];
      text = ''
        install -m 0755 -o wwwrun -g wwwrun -d /var/lib/php/sessions/phpldapadmin
        '';
    };
    systemd.services.phpfpm-ldap = {
      after = lib.mkAfter [ "openldap.service" ];
      wants = [ "openldap.service" ];
    };
  };
}